File Coverage

blib/lib/Protocol/XMLRPC/Value/Boolean.pm

Criterion	Covered	Total	%
statement	60	60	100.0
branch	18	22	81.8
condition	2	3	66.6
subroutine	25	25	100.0
pod	3	4	75.0
total	108	114	94.7

package Protocol::XMLRPC::Value::Boolean;

use strict;
use warnings;

use base 'Protocol::XMLRPC::Value';

sub type {'boolean'}

sub parse {
    my $class = shift;
    my $string = shift;

    die "Invalid 'Boolean' value"
      unless defined $string && $string =~ m/^(?:0|false|1|true)$/;

    return $class->new($string, @_);
}

sub value {
    my $self = shift;

    if (@_) {
        my $value = shift;

        if (ref($value) eq 'SCALAR') {
            $value = $$value ? 1 : 0;
        }
        else {
            $value = $value eq 'true' ? 1 : $value eq 'false' ? 0 : !!$value;
        }

        $self->{value} =
          $value
          ? Protocol::XMLRPC::Value::_True->new
          : Protocol::XMLRPC::Value::_False->new;

        return $self;
    }

    return $self->{value};
}

sub to_string {
    my $self = shift;

    my $value = $self->value;

    return "$value";
}

package Protocol::XMLRPC::Value::_True;

use overload '""'   => sub {'true'}, fallback => 1;
use overload 'bool' => sub {1},      fallback => 1;
use overload 'eq' => sub { $_[1] eq 'true' ? 1 : 0; }, fallback => 1;
use overload '==' => sub { $_[1] == 1 ? 1 : 0; }, fallback => 1;

sub new { bless {}, $_[0] }

package Protocol::XMLRPC::Value::_False;

use overload '""'   => sub {'false'}, fallback => 1;
use overload 'bool' => sub {0},       fallback => 1;
use overload 'eq' => sub { $_[1] eq 'false' ? 1 : 0; }, fallback => 1;
use overload '==' => sub { $_[1] == 0 ? 1 : 0; }, fallback => 1;

sub new { bless {}, $_[0] }

1;
__END__