File Coverage

blib/lib/Protocol/WebSocket/Handshake/Server.pm

Criterion	Covered	Total	%
statement	50	52	96.1
branch	15	16	93.7
condition	9	9	100.0
subroutine	10	11	90.9
pod	6	6	100.0
total	90	94	95.7

package Protocol::WebSocket::Handshake::Server;

use strict;
use warnings;

use base 'Protocol::WebSocket::Handshake';

use Protocol::WebSocket::Request;
use Protocol::WebSocket::Frame;

sub new_from_psgi {
    my $class = shift;

    my $req = Protocol::WebSocket::Request->new_from_psgi(@_);
    my $self = $class->new(req => $req);

    return $self;
}

sub parse {
    my $self = shift;

    my $req = $self->req;
    my $res = $self->res;

    return 1 if $req->is_done;

    unless ($req->parse($_[0])) {
        $self->error($req->error);
        return;
    }

    if ($req->is_body || $req->is_done) {
        $res->version($req->version);
        $res->host($req->host);

        $res->secure($req->secure);
        $res->resource_name($req->resource_name);
        $res->origin($req->origin);
    }

    if ($req->version eq 'draft-ietf-hybi-00') {
        if ($self->is_done) {
            $res->checksum(undef);
            $res->number1($req->number1);
            $res->number2($req->number2);
            $res->challenge($req->challenge);
        }
        else {
            $res->checksum('');
        }
    }
    elsif ($self->is_done && $req->version eq 'draft-ietf-hybi-10'
        || $req->version eq 'draft-ietf-hybi-17')
    {
        $res->key($req->key);
    }

    return 1;
}

sub is_body   { shift->req->is_body }
sub is_done   { shift->req->is_done }
sub to_string {
    my $self = shift;

    if ($self->is_body) {
        return $self->{partial} = $self->res->to_string;
    }
    elsif ($self->{partial}) {
        my $to_string = $self->res->to_string;

        $to_string =~ s/^\Q$self->{partial}\E//;

        return $to_string;
    }

    return $self->res->to_string;
}

sub build_frame {
    my $self = shift;

    return Protocol::WebSocket::Frame->new(version => $self->version, @_);
}

1;
__END__