File Coverage

blib/lib/Proc/JobQueue/DependencyJob.pm

Criterion	Covered	Total	%
statement	15	56	26.7
branch	0	18	0.0
condition	0	5	0.0
subroutine	5	11	45.4
pod	3	6	50.0
total	23	96	23.9

package Proc::JobQueue::DependencyJob;

use strict;
use warnings;
use Scalar::Util qw(blessed);
use Callback;
require Proc::JobQueue::Job;
use Carp qw(confess);

our @ISA = qw(Proc::JobQueue::Job);

sub new
{
	my ($pkg, $dependency_graph, $func, %params) = @_;
	$params{args} ||= [];

	my $cb = (blessed($func) && $func->isa('Callback'))
		? $func
		: Callback->new($func, @{$params{args}});

	delete $params{args};

	my $job = $pkg->SUPER::new(
		dependency_graph	=> $dependency_graph,
		dep_cb			=> $cb,
		started			=> 0,
		runnable		=> 0,
		%params,
	);
	$dependency_graph->add($job);
	return $job;
}

sub startup
{
	my ($job) = @_;

	my $host = $job->{host};
	my $jobnum = $job->{jobnum};
	my $job_queue = $job->{queue};

	my $cb = $job->{dep_cb};
	$job->{dep_cb} = undef;
	my ($code, $f, @a) = $cb->call($job);
	if ($code eq 'job-done,dep-keep') {
		$job->{dep_cb} = new Callback ($f, @a);
		$job_queue->jobdone($job);
	} elsif ($code eq 'all-done') {
		$job->finished(0);
	} elsif ($code eq 'job-keep,dep-done') {
		$job->{dependency_graph}->remove_dependency($job);
		undef $job->{dependency_graph};
	} elsif ($code eq 'all-keep') {
		# okay
	} else {
		die "unknown code '$code' from $job->{desc}";
	}
}

sub job_part_finished
{
	my ($job, $do_startmore) = @_;
	my $queue = $job->{queue};
	return unless $queue;
	$job->{queue} = undef;
	$queue->job_part_finished($job, $do_startmore);
}

sub success
{
	my ($job) = @_;
	if ($job->{dependency_graph}) {
		$job->{dependency_graph}->remove_dependency($job);
		undef $job->{dependency_graph};
	}
	$job->SUPER::success();
}

sub failed
{
	my ($job, @exit_code) = @_;
	if ($job->{dependency_graph}) {
		$job->{dependency_graph}->stuck_dependency($job);
		undef $job->{dependency_graph};
	}
	print STDERR "Job $job->{desc} failed, all dependent tasks cancelled\n";
}

sub failure
{
	my ($job, @exit_code) = @_;
	if ($exit_code[0]) {
		$job->finished(@exit_code);
	} else {
		$job->finished('FAILED', @exit_code);
	}
}

1;

__END__