File Coverage

blib/lib/Pod/Markdown/Githubert.pm

Criterion	Covered	Total	%
statement	55	71	77.4
branch	13	22	59.0
condition	1	5	20.0
subroutine	10	12	83.3
pod	3	7	42.8
total	82	117	70.0

package Pod::Markdown::Githubert;
use strict;
use warnings;

use Pod::Markdown ();
our @ISA = 'Pod::Markdown';

our $VERSION = '0.05';

sub new {
    my $class = shift;
    my %args = @_;

    my $hl_language = '';
    if (exists $args{hl_language}) {
        $hl_language = delete $args{hl_language};
    }

    my $self = $class->SUPER::new(
        markdown_fragment_format => sub {
            my ($self, $str) = @_;
            $str =~ tr/A-Za-z0-9_\- //cd;
            $str =~ tr/A-Z /a-z-/;
            $str
        },
        html_encode_chars => '\$',
        %args
    );
    $self->accept_targets('highlighter', 'github-markdown');
    $self->hl_language($hl_language);
    $self
}

sub hl_language {
    my $self = shift;
    if (@_) {
        $self->{+__PACKAGE__}{hl_language} = $_[0];
    }
    $self->{+__PACKAGE__}{hl_language}
}

sub format_perldoc_url {
    my $self = shift;
    my ($name, $section) = @_;
    my $prev_url_prefix;
    if (defined $name && $name =~ /\Aperl[a-z0-9]*\z/) {
        $prev_url_prefix = $self->perldoc_url_prefix;
        $self->perldoc_url_prefix('https://perldoc.perl.org/');
    }
    my $url = $self->SUPER::format_perldoc_url($name, $section);
    $self->perldoc_url_prefix($prev_url_prefix) if defined $prev_url_prefix;
    $url
}

sub start_for {
    my $self = shift;
    my ($attr) = @_;
    if ($attr->{target} eq 'highlighter') {
        $self->_new_stack;
        $self->_stack_state->{for_highlighter} = 1;
        return;
    }
    $self->SUPER::start_for(@_)
}

sub end_for {
    my $self = shift;
    my ($attr) = @_;
    if ($self->_stack_state->{for_highlighter}) {
        my $text = $self->_pop_stack_text;
        my %settings =
            map /\A([^=]*)=(.*)\z/s
                ? ($1 => $2)
                : (language => $_),
            split ' ', $text;
        $self->{+__PACKAGE__}{hl_language} = $settings{language} // '';
        return;
    }
    $self->SUPER::end_for(@_)
}

sub _indent_verbatim {
    my $self = shift;
    my ($paragraph) = @_;
    my $min_indent = 'inf';
    while ($paragraph =~ /^( +)/mg) {
        my $n = length $1;
        $min_indent = $n if $n < $min_indent;
    }
    my $rep =
        $min_indent < 'inf'
            ? "{$min_indent}"
            : '+';
    $paragraph =~ s/^ $rep//mg;
    my $fence = '```';
    while ($paragraph =~ /^ *\Q$fence\E *$/m) {
        $fence .= '`';
    }
    my $hl_language = $self->{+__PACKAGE__}{hl_language};
    if ($hl_language !~ /\A[^`\s]\S*\z/) {
        $hl_language = '';
    }
    "$fence$hl_language\n$paragraph\n$fence"
}

sub end_item_number {
    my $self = shift;
    if ($self->_last_string =~ /\S/) {
        return $self->SUPER::end_item_number(@_);
    }
    $self->_end_item($self->_private->{item_number} . '. ');
}

sub start_I {
    my $self = shift;
    $self->_save('*');
}

1
__END__