File Coverage

blib/lib/PocketIO/Transport/Htmlfile.pm

Criterion	Covered	Total	%
statement	9	42	21.4
branch	0	4	0.0
condition	0	2	0.0
subroutine	3	8	37.5
pod	1	1	100.0
total	13	57	22.8

package PocketIO::Transport::Htmlfile;

use strict;
use warnings;

use base 'PocketIO::Transport::Base';

sub dispatch {
    my $self = shift;

    if ($self->{env}->{REQUEST_METHOD} eq 'GET') {
        return $self->_dispatch_stream;
    }

    return $self->_dispatch_send;
}

sub _dispatch_stream {
    my $self = shift;

    my $conn = $self->conn;

    my $handle = $self->{handle};

    return sub {
        my $close_cb =
          sub { $handle->close; $self->client_disconnected($conn); };
        $handle->on_eof($close_cb);
        $handle->on_error($close_cb);

        $handle->on_heartbeat(sub { $conn->send_heartbeat });

        $handle->write(
            join "\x0d\x0a" => 'HTTP/1.1 200 OK',
            'Content-Type: text/html',
            'Connection: keep-alive',
            'Transfer-Encoding: chunked',
            'Access-Control-Allow-Origin: *',
            'Access-Control-Allow-Credentials: *',
            '',
            sprintf('%x', 173 + 83),
            'var _ = function (msg) { parent.s._(msg, document); };'
              . (' ' x 173),
            ''
        );

        $conn->on(
            write => sub {
                my $conn = shift;
                my ($message) = @_;

                $message = $self->_format_message($message);

                $handle->write(
                    join "\x0d\x0a" => sprintf('%x', length($message)),
                    $message,
                    ''
                );
            }
        );

        $conn->on(close => $close_cb);

        $self->client_connected($conn);
    };
}

sub _dispatch_send {
    my $self = shift;

    my $content_length = $self->{env}->{CONTENT_LENGTH} || 0;
    my $rcount =
      $self->{env}->{'psgi.input'}->read(my $chunk, $content_length);

    PocketIO::Exception->throw(500) unless $rcount == $content_length;

    $self->conn->parse_message($chunk);

    return [200, ['Content-Length' => 1], ['1']];
}

sub _format_message {
    my $self = shift;
    my ($message) = @_;

    $message =~ s/"/\\"/g;
    return qq{_("$message");};
}

1;
__END__