File Coverage

blib/lib/PlackX/MiddlewareStack.pm

Criterion	Covered	Total	%
statement	22	52	42.3
branch	1	4	25.0
condition			n/a
subroutine	8	13	61.5
pod	0	6	0.0
total	31	75	41.3

package PlackX::MiddlewareStack;
use strict;
use warnings;
use 5.008_001;
our $VERSION = '0.011';

use Tie::LLHash;

sub new {
    my $class       = shift;
    my %middlewares = ();
    tie( %middlewares, 'Tie::LLHash' );
    bless { middlewares => \%middlewares }, $class;
}

sub add {
    my ( $self, $mw_class, $args ) = @_;

    my $mw = $self->_to_middleware( $mw_class, $args );
    ( tied %{ $self->{middlewares} } )->last( $mw_class => $mw );
}

sub insert_after {
    my ( $self, $mw_class_to_add, $args, $target_mw_class ) = @_;

    my $mw = $self->_to_middleware( $mw_class_to_add, $args );
    ( tied %{ $self->{middlewares} } )
        ->insert( $mw_class_to_add => $mw, $target_mw_class );
}

sub insert_before {
    my ( $self, $mw_class_to_add, $args, $target_mw_class ) = @_;

    my $mw = $self->_to_middleware( $mw_class_to_add, $args );
    my $before_target
        = ( tied %{ $self->{middlewares} } )->key_before($target_mw_class);
    ( tied %{ $self->{middlewares} } )
        ->insert( $mw_class_to_add => $mw, $before_target );
}

sub to_app {
    my ( $self, $app ) = @_;

    for my $mw_class ( reverse keys %{ $self->{middlewares} } ) {
        my $mw = $self->{middlewares}->{$mw_class};
        $app = $mw->($app);
    }
    $app;
}

sub _to_middleware {
    my ( $self, $mw_class, $args ) = @_;

    eval "use $mw_class";
    die $@ if $@;

    my @args = ();
    while ( my ( $key, $value ) = each( %{ $args || {} } ) ) {
        push @args, $key;
        push @args, $value;
    }

    my $mw = sub { $mw_class->wrap( $_[0], @args ) };
    $mw;
}

sub middleware_classes {
    keys %{ shift->{middlewares} };
}

1;

__END__