File Coverage

blib/lib/Plack/Middleware/UnicodePictogramFallback/TypeCast.pm

Criterion	Covered	Total	%
statement	22	24	91.6
branch			n/a
condition			n/a
subroutine	8	8	100.0
pod			n/a
total	30	32	93.7

package Plack::Middleware::UnicodePictogramFallback::TypeCast;
use 5.008_001;
use strict;
use warnings;
use utf8;

our $VERSION = '0.02';

use Plack::Util;
use Plack::Middleware::UnicodePictogramFallback::TypeCast::EmoticonMap;
use Encode qw/encode_utf8 decode/;
use Encode::JP::Mobile ':props';
use Encode::JP::Mobile::UnicodeEmoji;

use parent 'Plack::Middleware';
use Plack::Util::Accessor qw(
    template
    fallback
);

sub prepare_app {
    my $self = shift;

    die 'requires template' unless $self->template;
}

sub call {
    my ($self, $env) = @_;
    my $res = $self->app->($env);

    my $h = Plack::Util::headers($res->[1]);
    return $res if $h->get('Content-Type') !~ m!^text/!;

    $self->response_cb($res, sub {
        my $res = shift;
        return sub {
            my $chunk = shift;
            return unless defined $chunk;

            $self->_filter($chunk);
        };
    });
}

sub _filter {
    my ($self, $html) = @_;

    $html = decode('x-utf8-jp-mobile-unicode-emoji', $html);
    my $emoticon_map = Plack::Middleware::UnicodePictogramFallback::TypeCast::EmoticonMap::MAP;

    my $fallback = $self->fallback || sub {'〓'};
    $html =~ s{(\p{InMobileJPPictograms})}{
        my $char = $1;
        my $code = sprintf '%X', ord $char;

        if (my $name = $emoticon_map->{$code}) {
            sprintf $self->template, $name, $char;
        } else {
            encode_utf8 $fallback->($char);
        }
    }ge;

    encode_utf8 $html;
}

1;
__END__