File Coverage

blib/lib/Plack/Middleware/Static/OpenFileCache.pm

Criterion	Covered	Total	%
statement	45	56	80.3
branch	14	20	70.0
condition	4	9	44.4
subroutine	9	11	81.8
pod	1	1	100.0
total	73	97	75.2

package Plack::Middleware::Static::OpenFileCache;

use 5.008005;
use strict;
use warnings;
use parent qw/Plack::Middleware::Static/;
use Plack::Util::Accessor qw(max expires buf_size cache_errors);
use Cache::LRU::WithExpires;

our $VERSION = "0.02";

sub prepare_app {
    my $self = shift;
    my $max = $self->max;
    $max = 100 unless defined $max;
    $self->expires(60) unless defined $self->expires;
    $self->buf_size(8192) unless defined $self->buf_size;
    $self->{_cache_lru} = Cache::LRU::WithExpires->new(size => $max);
}

sub _handle_static {
    my($self, $env) = @_;
    my $path = $env->{PATH_INFO};
    my $cache = $self->{_cache_lru};
    my $res = $cache->get($path);
    if ( $res ) {
        if ( ref $res->[2] ne 'ARRAY' ) {
            seek($res->[2],0,0);
        }
        return $res;
    }
    $res = $self->SUPER::_handle_static($env);
    return unless defined $res;
    if ( ref $res->[2] ne 'ARRAY' ) {
        my $len = Plack::Util::header_get($res->[1], 'Content-Length');
        if ( $self->{buf_size} && $len && $len < $self->{buf_size} ) {
            local $/ = 65536;
            my $buf = $res->[2]->getline;
            $res->[2] = [$buf];
        }
        else {
            my $io_path = $res->[2]->path;
            bless $res->[2], 'Plack::Middleware::Static::OpenFileCache::IOWithPath';
            $res->[2]->path($io_path);
        }
    }
    if ( $res->[0] =~ m!^2! or $self->cache_errors ) {
        $cache->set($path, $res, $self->expires);
    }
    $res;
}

package Plack::Middleware::Static::OpenFileCache::IOWithPath;
use parent qw(IO::Handle);

sub path {
    my $self = shift;
    if (@_) {
        ${*$self}{+__PACKAGE__} = shift;
    }
    ${*$self}{+__PACKAGE__};
}

sub close {}

1;
__END__