File Coverage

blib/lib/Plack/Middleware/Options.pm

Criterion	Covered	Total	%
statement	28	29	96.5
branch	9	10	90.0
condition			n/a
subroutine	5	5	100.0
pod	2	2	100.0
total	44	46	95.6

package Plack::Middleware::Options;

use strict;
use warnings;
use parent 'Plack::Middleware';

our $VERSION = '0.01';

my @HTTP_METHODS = qw/CONNECT DELETE GET HEAD POST PUT TRACE/;

sub prepare_app {
    my ( $self ) = @_;

    my $allowed = $self->{'allowed'};
    if(ref $allowed eq 'ARRAY') {
        $allowed = { map { $_ => 1 } @$allowed };
    } elsif(ref $allowed ne 'HASH') {
        $allowed = {
            map { $_ => 1 } @HTTP_METHODS,
        };
    }
    $self->{'allowed'} = $allowed;
}

sub call {
    my ( $self, $env ) = @_;

    my $method = $env->{'REQUEST_METHOD'};

    if($method eq 'OPTIONS') {
        my @allowed;

        if($env->{'REQUEST_URI'} eq '*') {
            @allowed = @HTTP_METHODS;
        } else {
            @allowed = keys %{ $self->{'allowed'} };
        }

        return [
            200,
            ['Allow' => join(', ', @allowed)],
            [],
        ];
    } elsif(exists $self->{'allowed'}{$method}) {
        return $self->app->($env);
    } else {
        return [
            405,
            [
                'Allow'        => join(', ', keys %{ $self->{'allowed'} }),
                'Content-Type' => 'text/plain',
            ],
            ['Method not allowed'],
        ];
    }
};

1;

__END__