File Coverage

blib/lib/Plack/Middleware/JavaScript/Ectype.pm

Criterion	Covered	Total	%
statement	9	9	100.0
branch			n/a
condition			n/a
subroutine	3	3	100.0
pod			n/a
total	12	12	100.0

package Plack::Middleware::JavaScript::Ectype;

use strict;
use warnings;
use parent qw/Plack::Middleware/;
use HTTP::Date;
use Plack::Util;
use Plack::Util::Accessor qw/prefix root minify/;
use Carp;
use JavaScript::Ectype::Loader;

our $VERSION = q(0.0.1);

sub call{
    my ($self,$env) = @_;
    return $self->_handler( $env ) || $self->app->($env);
}

sub expire_time{
    my $self = shift;
    return $self->{expire_time} || 60 * 60 * 24 * 14;
}

sub _handler{
    my ($self,$env) = @_;

    return unless defined $self->prefix;
    return unless defined $self->root;
    return unless my $fqn = $self->_get_fqn( $env );


    my $jel = JavaScript::Ectype::Loader->new(
        path   => $self->root,
        target => $fqn,
        minify => int($self->minify)
    );
    my $ims = $self->_get_modified_since($env) || 0;
    return $self->_not_found()    unless -e $jel->file_path;
    return $self->_not_modified() unless $jel->is_modified_from($ims);
    $jel->load_content;

    my $content = $jel->get_content;
    my $last_modified = $jel->newest_mtime;
    return [
        200,
        [
            'Content-Type'   => 'text/javascript',
            'Content-Length' => length $content,
            'Last-Modified'  => HTTP::Date::time2str($last_modified),
            'Expires'        => HTTP::Date::time2str( time() + $self->expire_time )
        ],
        [$content]
    ];

}
sub _not_found {
    my ($self) = @_;
    return [404,[],[]];
}

sub _not_modified {
    my ($self ) = @_;
    return [304,[Expires => HTTP::Date::time2str( time() + $self->expire_time )],[]]
}

sub _get_fqn {
    my ( $self, $env ) = @_;
    my $uri    = $env->{REQUEST_URI};
    my $prefix = $self->prefix;
    if ( $uri =~ m/$prefix([a-zA-Z0-9._]+)/ ){
        return $1;
    }
    return;
}

sub _get_modified_since{
    my ($self,$env) = @_;
    return HTTP::Date::str2time( $env->{HTTP_IF_MODIFIED_SINCE} );
}

1;
__END__