File Coverage

blib/lib/Plack/Middleware/EmulateOPTIONS.pm

Criterion	Covered	Total	%
statement	43	43	100.0
branch	6	6	100.0
condition	6	6	100.0
subroutine	11	11	100.0
pod	2	2	100.0
total	68	68	100.0

package Plack::Middleware::EmulateOPTIONS;

# ABSTRACT: handle OPTIONS requests as HEAD

use v5.20;

use warnings;

use parent 'Plack::Middleware';

use Plack::Util;
use Plack::Util::Accessor qw( filter callback );
use HTTP::Status          ();

use experimental qw( postderef signatures );

our $VERSION = 'v0.4.0';


sub prepare_app($self) {

    unless ( defined $self->callback ) {

        $self->callback(
            sub( $res, $env ) {
                Plack::Util::header_set( $res->[1], 'allow', "GET, HEAD, OPTIONS" );
            }
        );

    }
}

sub call( $self, $env ) {

    my $filter   = $self->filter;
    my $callback = $self->callback;

    if ( $env->{REQUEST_METHOD} eq "OPTIONS" && ( !$filter || $filter->($env) ) ) {

        my $res = $self->app->( { $env->%*, REQUEST_METHOD => "HEAD" } );

        return Plack::Util::response_cb(
            $res,
            sub {
                my ($res) = @_;
                if ( HTTP::Status::is_success( $res->[0] ) ) {
                    $callback->( $res, $env );
                }
            }
        );

    }
    else {

        return $self->app->($env);

    }
}


1;

__END__