File Coverage

blib/lib/Plack/Middleware/CSS/Compressor.pm

Criterion	Covered	Total	%
statement	39	42	92.8
branch	6	12	50.0
condition	2	6	33.3
subroutine	9	9	100.0
pod	2	2	100.0
total	58	71	81.6

package Plack::Middleware::CSS::Compressor;

use strict;
use warnings;

use parent qw( Plack::Middleware );

use CSS::Compressor qw( css_compress );

use Plack::Util::Accessor qw( suffix );
use Plack::Util;

our $VERSION = '0.01';

sub prepare_app
{
	my $self = shift;
	my $suffix = $self->suffix();

	unless ( defined( $suffix ) ) {
		$suffix = '-min';
	}

	# make the suffix usable in regular expressions
	$self->suffix( ref( $suffix )
		? $suffix
		: quotemeta( $suffix )
	);
}

sub call
{
	my ( $self, $env ) = @_;
	my $suffix = $self->suffix();
	my $path_info = $env->{PATH_INFO};

	# match and adjust file name and extension
	unless ( $env->{PATH_INFO} =~ s!\A (.*) $suffix ([.]css) \z!$1$2!x ) {
		# otherwise pass through
		return $self->app->( $env );
	}

	# call underlying handler with adjusted path
	my $res = $self->app->( $env );

	# make sure the response is an array and not streamed
	unless ( ref( $res ) eq 'ARRAY' ) {
		return $res;
	}

	my $h = Plack::Util::headers( $res->[1] );
	my $ct = $h->get( 'Content-Type' );

	# got a stylesheet as response
	if ( $res->[0] == 200 && $ct && $ct =~ m!\A text/css \b!x ) {
		my $css = '';

		# collect all css chunks
		Plack::Util::foreach( $res->[2], sub { $css .= $_[0] } );

		# store compressed css as new body
		$res->[2] = [ css_compress( $css ) ];

		# adjust length
		$h->set( 'Content-Length' => length( $res->[2][0] ) );
	}
	# nothing found with the adjusted path
	elsif ( $res->[0] == 404 ) {
		# restore original path
		$env->{PATH_INFO} = $path_info;
		# and try again
		$res = $self->app->( $env );
	}

	return $res;
}

1;

__END__