File Coverage

blib/lib/Plack/App/Tags/HTML.pm

Criterion	Covered	Total	%
statement	73	74	98.6
branch	22	28	78.5
condition			n/a
subroutine	12	12	100.0
pod			n/a
total	107	114	93.8

package Plack::App::Tags::HTML;

use base qw(Plack::Component::Tags::HTML);
use strict;
use warnings;

use English;
use Error::Pure qw(err);
use Plack::Util::Accessor qw(component constructor_args data data_css data_init data_prepare);
use Symbol::Get;

our $VERSION = 0.19;

sub _css {
	my ($self, $env) = @_;

	my @data_css;
	if (defined $self->data_css) {
		push @data_css, @{$self->data_css};
	}

	$self->{'_component'}->process_css(@data_css);

	return;
}

sub _loaded_component {
	my ($self, $component) = @_;

	my @names = eval {
		Symbol::Get::get_names($component);
	};
	if ($EVAL_ERROR) {
		return 0;
	}

	return 1;
}

sub _prepare_app {
	my $self = shift;

	$self->SUPER::_prepare_app();

	my %p = (
		'css' => $self->css,
		'tags' => $self->tags,
	);

	my $component = $self->component;
	if (! $self->_loaded_component($component)) {
		eval "require $component;";
		if ($EVAL_ERROR) {
			err "Cannot load component '$component'.",
				'Error', $EVAL_ERROR;
		}
	}
	$self->{'_component'} = $component->new(
		%p,
		defined $self->constructor_args ? (
			%{$self->constructor_args},
		) : (),
	);
	if (! $self->{'_component'}->isa('Tags::HTML')) {
		err "Component must be a instance of 'Tags::HTML' class.";
	}

	# Init prepared data.
	if ($self->{'_component'}->can('prepare')) {
		my @data = ();
		if (defined $self->data_prepare) {
			push @data, @{$self->data_prepare};
		}
		$self->{'_component'}->prepare(@data);
	}

	# Copy CSS links from component to main object.
	if ($self->{'_component'}->can('css_src')) {
		$self->css_src($self->{'_component'}->css_src);
	}

	# Copy Javascript links from component to main object.
	if ($self->{'_component'}->can('script_js_src')) {
		$self->script_js_src($self->{'_component'}->script_js_src);
	}

	return;
}

sub _process_actions {
	my ($self, $env) = @_;

	if ($self->{'_component'}->can('init')) {
		if (defined $self->data_init) {
			$self->{'_component'}->init(@{$self->data_init});
		} else {
			$self->{'_component'}->init;
		}
	}

	# Copy Javascript code from component to main object.
	if ($self->{'_component'}->can('script_js')) {
		$self->script_js($self->{'_component'}->script_js);
	}

	# Init begin of page.
	$self->SUPER::_process_actions($env);

	return;
}

sub _tags_middle {
	my ($self, $env) = @_;

	my @data;
	if (defined $self->data) {
		push @data, @{$self->data};
	}
	$self->{'_component'}->process(@data);

	return;
}

1;

__END__