File Coverage

blib/lib/Plack/App/Hash.pm

Criterion	Covered	Total	%
statement	53	53	100.0
branch	18	18	100.0
condition	12	18	66.6
subroutine	11	11	100.0
pod	2	3	66.6
total	96	103	93.2

use 5.006; use strict; use warnings;

package Plack::App::Hash;

our $VERSION = '1.001';

BEGIN { require Plack::Component; our @ISA = 'Plack::Component' }

use Plack::Util ();
use Array::RefElem ();
use HTTP::Status ();
#use Digest::SHA;

use Plack::Util::Accessor qw( content headers auto_type default_type );

sub prepare_app {
	my $self = shift;
	require Plack::MIME if $self->auto_type;
}

sub call {
	my $self = shift;
	my $env  = shift;

	my $path = $env->{'PATH_INFO'};
	$path =~ s!\A/!!;

	my $content = $self->content;
	return $self->error( 404 ) unless $content and exists $content->{ $path };
	return $self->error( 500 ) if ref $content->{ $path };

	my $headers = ( $self->headers || $self->headers( {} ) )->{ $path };

	if ( not defined $headers ) {
		$headers = [];
	}
	elsif ( not ref $headers ) {
		require JSON::MaybeXS;
		$headers = JSON::MaybeXS::decode_json $headers;
	}

	return $self->error( 500 ) if 'ARRAY' ne ref $headers;

	{
		my $auto    = $self->auto_type;
		my $default = $self->default_type;
		last unless $auto or $default;
		last if Plack::Util::header_exists $headers, 'Content-Type';
		$auto &&= Plack::MIME->mime_type( $path );
		push @$headers, 'Content-Type' => $_ for $auto || $default || ();
	}

	if ( not Plack::Util::header_exists $headers, 'Content-Length' ) {
		push @$headers, 'Content-Length' => length $content;
	}

	my @body;
	Array::RefElem::av_push @body, $content->{ $path };
	return [ 200, $headers, \@body ];
}

sub error {
	my $status = pop;
	my $pkg = __PACKAGE__;
	my $body = [ qq(\n$pkg $status) . HTTP::Status::status_message $status ];
	return [ $status, [
		'Content-Type'   => 'text/html',
		'Content-Length' => length $body->[0],
	], $body ];
}

1;

__END__