File Coverage

blib/lib/Plack/App/Directory/Xslate.pm

Criterion	Covered	Total	%
statement	9	9	100.0
branch			n/a
condition			n/a
subroutine	3	3	100.0
pod			n/a
total	12	12	100.0

package Plack::App::Directory::Xslate;
use strict;
use warnings;

our $VERSION = '0.07';

use parent qw(Plack::App::Directory);

use Text::Xslate;
use Encode ();
use File::Spec;

use Plack ();
use Plack::App::File ();
use Plack::Util ();
use Plack::Util::Accessor qw(xslate_opt xslate_path xslate_param);

sub new {
    my $class = shift;
    my $self  = $class->SUPER::new(@_);

    $self->xslate_opt->{path} = $self->root;
    $self->{xslate}           = Text::Xslate->new($self->xslate_opt);
    $self->{encoder}          = Encode::find_encoding('utf-8');
    $self->xslate_param(+{}) unless $self->xslate_param;

    $self->xslate_path(sub {}) unless $self->xslate_path;
    if (ref $self->xslate_path eq 'Regexp') {
        my $re = $self->xslate_path;
        $self->xslate_path(sub { $_ =~ $re });
    }

    return $self;
}

sub serve_path {
    my ($self, $env, $path, $fullpath) = @_;

    if (-f $path && $self->is_xslate_path($path)) {
        return $self->serve_xslate($env, $path, $fullpath);
    }
    else {
        return $self->SUPER::serve_path($env, $path, $fullpath);
    }
}

sub is_xslate_path {
    my ($self, $path) = @_;

    local $_ = $path;
    return $self->xslate_path->($path);
}

sub serve_xslate {
    my ($self, $env, $path, $fullpath) = @_;

    my $tmpl_path = File::Spec->abs2rel($path, $self->root);
    my $content   = $self->{encoder}->encode(
        $self->{xslate}->render($tmpl_path, $self->xslate_param)
    );
    return [
        200,
        [
            'Content-Type'   => 'text/html',
            'Content-Length' => Plack::Util::content_length($content),
        ],
        [$content]
    ];
}

1;
__END__