File Coverage

blib/lib/Pithub/Repos.pm

Criterion	Covered	Total	%
statement	119	119	100.0
branch	15	18	83.3
condition			n/a
subroutine	47	47	100.0
pod	29	29	100.0
total	210	213	98.5

package Pithub::Repos;
our $AUTHORITY = 'cpan:PLU';

# ABSTRACT: Github v3 Repos API

use Moo;

our $VERSION = '0.01043';

use Carp                         qw( croak );
use Pithub::Issues               ();
use Pithub::Markdown             ();
use Pithub::PullRequests         ();
use Pithub::Repos::Actions       ();
use Pithub::Repos::Collaborators ();
use Pithub::Repos::Commits       ();
use Pithub::Repos::Contents      ();
use Pithub::Repos::Downloads     ();
use Pithub::Repos::Forks         ();
use Pithub::Repos::Hooks         ();
use Pithub::Repos::Keys          ();
use Pithub::Repos::Releases      ();
use Pithub::Repos::Starring      ();
use Pithub::Repos::Stats         ();
use Pithub::Repos::Statuses      ();
use Pithub::Repos::Watching      ();

extends 'Pithub::Base';


sub actions {
    return shift->_create_instance( Pithub::Repos::Actions::, @_ );
}


sub branch {
    my ( $self, %args ) = @_;
    croak 'Missing key in parameters: branch (string)'
        unless defined $args{branch};
    $self->_validate_user_repo_args( \%args );
    return $self->request(
        method => 'GET',
        path   => sprintf(
            '/repos/%s/%s/branches/%s', delete $args{user},
            delete $args{repo},
            delete $args{branch},
        ),
        %args,
    );
}


sub branches {
    my ( $self, %args ) = @_;
    $self->_validate_user_repo_args( \%args );
    return $self->request(
        method => 'GET',
        path   => sprintf(
            '/repos/%s/%s/branches', delete $args{user}, delete $args{repo}
        ),
        %args,
    );
}


sub rename_branch {
    my ( $self, %args ) = @_;
    croak 'Missing parameters: branch' unless $args{branch};
    croak 'Missing key in parameters: data (hashref)'
        unless ref $args{data} eq 'HASH';
    $self->_validate_user_repo_args( \%args );
    return $self->request(
        method => 'POST',
        path   => sprintf(
            '/repos/%s/%s/branches/%s/rename', delete $args{user},
            delete $args{repo},                delete $args{branch}
        ),
        %args,
    );
}


sub merge_branch {
    my ( $self, %args ) = @_;
    croak 'Missing key in parameters: data (hashref)'
        unless ref $args{data} eq 'HASH';
    $self->_validate_user_repo_args( \%args );
    return $self->request(
        method => 'POST',
        path   => sprintf(
            '/repos/%s/%s/merges', delete $args{user}, delete $args{repo}
        ),
        %args,
    );
}


sub collaborators {
    return shift->_create_instance( Pithub::Repos::Collaborators::, @_ );
}


sub commits {
    return shift->_create_instance( Pithub::Repos::Commits::, @_ );
}


sub contents {
    return shift->_create_instance( Pithub::Repos::Contents::, @_ );
}


sub contributors {
    my ( $self, %args ) = @_;
    $self->_validate_user_repo_args( \%args );
    return $self->request(
        method => 'GET',
        path   => sprintf(
            '/repos/%s/%s/contributors', delete $args{user},
            delete $args{repo}
        ),
        %args,
    );
}


sub create {
    my ( $self, %args ) = @_;
    croak 'Missing key in parameters: data (hashref)'
        unless ref $args{data} eq 'HASH';
    if ( my $org = delete $args{org} ) {
        return $self->request(
            method => 'POST',
            path   => sprintf( '/orgs/%s/repos', $org ),
            %args,
        );
    }
    else {
        return $self->request(
            method => 'POST',
            path   => '/user/repos',
            %args,
        );
    }
}


sub delete {
    my ( $self, %args ) = @_;
    $self->_validate_user_repo_args( \%args );
    return $self->request(
        method => 'DELETE',
        path   =>
            sprintf( '/repos/%s/%s', delete $args{user}, delete $args{repo} ),
        %args,
    );
}


sub downloads {
    return shift->_create_instance( Pithub::Repos::Downloads::, @_ );
}


sub forks {
    return shift->_create_instance( Pithub::Repos::Forks::, @_ );
}


sub get {
    my ( $self, %args ) = @_;
    $self->_validate_user_repo_args( \%args );
    return $self->request(
        method => 'GET',
        path   =>
            sprintf( '/repos/%s/%s', delete $args{user}, delete $args{repo} ),
        %args,
    );
}


sub hooks {
    return shift->_create_instance( Pithub::Repos::Hooks::, @_ );
}


sub issues {
    return shift->_create_instance( Pithub::Issues::, @_ );
}


sub keys {
    return shift->_create_instance( Pithub::Repos::Keys::, @_ );
}


sub languages {
    my ( $self, %args ) = @_;
    $self->_validate_user_repo_args( \%args );
    return $self->request(
        method => 'GET',
        path   => sprintf(
            '/repos/%s/%s/languages', delete $args{user}, delete $args{repo}
        ),
        %args,
    );
}


sub list {
    my ( $self, %args ) = @_;
    if ( my $user = delete $args{user} ) {
        return $self->request(
            method => 'GET',
            path   => sprintf( '/users/%s/repos', $user ),
            %args,
        );
    }
    elsif ( my $org = delete $args{org} ) {
        return $self->request(
            method => 'GET',
            path   => sprintf( '/orgs/%s/repos', $org ),
            %args
        );
    }
    else {
        return $self->request(
            method => 'GET',
            path   => '/user/repos',
            %args,
        );
    }
}


sub markdown {
    my $self = shift;
    return $self->_create_instance(
        Pithub::Markdown::,
        mode    => 'gfm',
        context => sprintf( '%s/%s', $self->user, $self->repo ),
        @_
    );
}


sub pull_requests {
    return shift->_create_instance( Pithub::PullRequests::, @_ );
}


sub releases {
    return shift->_create_instance( Pithub::Repos::Releases::, @_ );
}


sub starring {
    return shift->_create_instance( Pithub::Repos::Starring::, @_ );
}


sub stats {
    return shift->_create_instance( Pithub::Repos::Stats::, @_ );
}


sub statuses {
    return shift->_create_instance( Pithub::Repos::Statuses::, @_ );
}


sub tags {
    my ( $self, %args ) = @_;
    $self->_validate_user_repo_args( \%args );
    return $self->request(
        method => 'GET',
        path   => sprintf(
            '/repos/%s/%s/tags', delete $args{user}, delete $args{repo}
        ),
        %args,
    );
}


sub teams {
    my ( $self, %args ) = @_;
    $self->_validate_user_repo_args( \%args );
    return $self->request(
        method => 'GET',
        path   => sprintf(
            '/repos/%s/%s/teams', delete $args{user}, delete $args{repo}
        ),
        %args,
    );
}


sub update {
    my ( $self, %args ) = @_;
    croak 'Missing key in parameters: data (hashref)'
        unless ref $args{data} eq 'HASH';
    $self->_validate_user_repo_args( \%args );
    return $self->request(
        method => 'PATCH',
        path   =>
            sprintf( '/repos/%s/%s', delete $args{user}, delete $args{repo} ),
        %args,
    );
}


sub watching {
    return shift->_create_instance( Pithub::Repos::Watching::, @_ );
}

1;

__END__