File Coverage

blib/lib/Pithub/Issues.pm

Criterion	Covered	Total	%
statement	44	44	100.0
branch	9	10	90.0
condition	2	3	66.6
subroutine	16	16	100.0
pod	9	9	100.0
total	80	82	97.5

package Pithub::Issues;
our $AUTHORITY = 'cpan:PLU';
our $VERSION = '0.01043';

# ABSTRACT: Github v3 Issues API

use Moo;
use Carp                       qw( croak );
use Pithub::Issues::Assignees  ();
use Pithub::Issues::Comments   ();
use Pithub::Issues::Events     ();
use Pithub::Issues::Labels     ();
use Pithub::Issues::Milestones ();
extends 'Pithub::Base';


sub assignees {
    return shift->_create_instance( Pithub::Issues::Assignees::, @_ );
}


sub comments {
    return shift->_create_instance( Pithub::Issues::Comments::, @_ );
}


sub create {
    my ( $self, %args ) = @_;
    croak 'Missing key in parameters: data (hashref)'
        unless ref $args{data} eq 'HASH';
    $self->_validate_user_repo_args( \%args );
    return $self->request(
        method => 'POST',
        path   => sprintf(
            '/repos/%s/%s/issues', delete $args{user}, delete $args{repo}
        ),
        %args,
    );
}


sub events {
    return shift->_create_instance( Pithub::Issues::Events::, @_ );
}


sub get {
    my ( $self, %args ) = @_;
    croak 'Missing key in parameters: issue_id' unless $args{issue_id};
    $self->_validate_user_repo_args( \%args );
    return $self->request(
        method => 'GET',
        path   => sprintf(
            '/repos/%s/%s/issues/%s', delete $args{user}, delete $args{repo},
            delete $args{issue_id}
        ),
        %args,
    );
}


sub labels {
    return shift->_create_instance( Pithub::Issues::Labels::, @_ );
}


sub list {
    my ( $self, %args ) = @_;
    $self->_get_user_repo_args( \%args );
    if ( $args{user} && $args{repo} ) {
        return $self->request(
            method => 'GET',
            path   => sprintf(
                '/repos/%s/%s/issues', delete $args{user}, delete $args{repo}
            ),
            %args,
        );
    }
    return $self->request(
        method => 'GET',
        path   => sprintf('/issues'),
        %args,
    );
}


sub milestones {
    return shift->_create_instance( Pithub::Issues::Milestones::, @_ );
}


sub update {
    my ( $self, %args ) = @_;
    croak 'Missing key in parameters: issue_id' unless $args{issue_id};
    croak 'Missing key in parameters: data (hashref)'
        unless ref $args{data} eq 'HASH';
    $self->_validate_user_repo_args( \%args );
    return $self->request(
        method => 'PATCH',
        path   => sprintf(
            '/repos/%s/%s/issues/%s', delete $args{user}, delete $args{repo},
            delete $args{issue_id}
        ),
        %args,
    );
}

1;

__END__