File Coverage

bin/rev

Criterion	Covered	Total	%
statement	38	49	77.5
branch	8	12	66.6
condition			n/a
subroutine	8	8	100.0
pod			n/a
total	54	69	78.2

#!/usr/bin/perl

=begin metadata

Name: rev
Description: reverse lines of a file
Author: Andy Murren, [e-mail]
License: gpl

=end metadata

=cut

use strict;

use File::Basename qw(basename);
use Getopt::Std qw(getopts);

use constant EX_SUCCESS => 0;
use constant EX_FAILURE => 1;

my $Program = basename($0);

# unbuffer output to make it look speedier
$|++;

our $VERSION = '1.5';

getopts('') or usage();
my $rc = EX_SUCCESS;
foreach my $file (@ARGV) {
	if (-d $file) {
		warn "$Program: '$file' is a directory\n";
		$rc = EX_FAILURE;
		next;
	}
	my $fh;
	unless (open $fh, '<', $file) {
		warn "$Program: cannot open '$file': $!\n";
		$rc = EX_FAILURE;
		next;
	}
	rev($fh);
	if ($!) {
		warn "$Program: '$file': $!\n";
		$rc = EX_FAILURE;
	}
	unless (close $fh) {
		warn "$Program: cannot close '$file': $!\n";
		$rc = EX_FAILURE;
		next;
	}
}
rev(*STDIN) unless @ARGV;
exit $rc;

sub rev {
	my $fh = shift;
	while (<$fh>) {
		chomp;
		my $r = reverse;
		print $r, $/;
	}
}

sub usage {
	print "usage: $Program [file ...]\n";
	exit EX_FAILURE;
}

sub VERSION_MESSAGE {
	print "$Program version $VERSION\n";
	exit EX_SUCCESS;
}

__END__