| 1 | #!/usr/bin/perl -w | ||
| 2 | # *************************************************************************** | ||
| 3 | # * _ _ ____ _ | ||
| 4 | # * Project ___| | | | _ \| | | ||
| 5 | # * / __| | | | |_) | | | ||
| 6 | # * | (__| |_| | _ <| |___ | ||
| 7 | # * \___|\___/|_| \_\_____| | ||
| 8 | # * | ||
| 9 | # * Copyright (C) 1998 - 2014, Daniel Stenberg, <daniel@haxx.se>, et al. | ||
| 10 | # * | ||
| 11 | # * This software is licensed as described in the file COPYING, which | ||
| 12 | # * you should have received as part of this distribution. The terms | ||
| 13 | # * are also available at http://curl.haxx.se/docs/copyright.html. | ||
| 14 | # * | ||
| 15 | # * You may opt to use, copy, modify, merge, publish, distribute and/or sell | ||
| 16 | # * copies of the Software, and permit persons to whom the Software is | ||
| 17 | # * furnished to do so, under the terms of the COPYING file. | ||
| 18 | # * | ||
| 19 | # * This software is distributed on an "AS IS" basis, WITHOUT WARRANTY OF ANY | ||
| 20 | # * KIND, either express or implied. | ||
| 21 | # * | ||
| 22 | # *************************************************************************** | ||
| 23 | # This Perl script creates a fresh ca-bundle.crt file for use with libcurl. | ||
| 24 | # It downloads certdata.txt from Mozilla's source tree (see URL below), | ||
| 25 | # then parses certdata.txt and extracts CA Root Certificates into PEM format. | ||
| 26 | # These are then processed with the OpenSSL commandline tool to produce the | ||
| 27 | # final ca-bundle.crt file. | ||
| 28 | # The script is based on the parse-certs script written by Roland Krikava. | ||
| 29 | # This Perl script works on almost any platform since its only external | ||
| 30 | # dependency is the OpenSSL commandline tool for optional text listing. | ||
| 31 | # Hacked by Guenter Knauf. | ||
| 32 | # | ||
| 33 | use Getopt::Std; | ||
| 34 | use MIME::Base64; | ||
| 35 | use LWP::UserAgent; | ||
| 36 | use strict; | ||
| 37 | use vars qw($opt_b $opt_d $opt_f $opt_h $opt_i $opt_l $opt_n $opt_p $opt_q $opt_s $opt_t $opt_u $opt_v $opt_w); | ||
| 38 | use List::Util; | ||
| 39 | use Text::Wrap; | ||
| 40 | my $MOD_SHA = "Digest::SHA"; | ||
| 41 | eval "require $MOD_SHA"; | ||
| 42 | if ($@) { | ||
| 43 | $MOD_SHA = "Digest::SHA::PurePerl"; | ||
| 44 | eval "require $MOD_SHA"; | ||
| 45 | } | ||
| 46 | |||
| 47 | my %urls = ( | ||
| 48 | 'nss' => | ||
| 49 | 'http://hg.mozilla.org/projects/nss/raw-file/tip/lib/ckfw/builtins/certdata.txt', | ||
| 50 | 'central' => | ||
| 51 | 'http://hg.mozilla.org/mozilla-central/raw-file/default/security/nss/lib/ckfw/builtins/certdata.txt', | ||
| 52 | 'aurora' => | ||
| 53 | 'http://hg.mozilla.org/releases/mozilla-aurora/raw-file/default/security/nss/lib/ckfw/builtins/certdata.txt', | ||
| 54 | 'beta' => | ||
| 55 | 'http://hg.mozilla.org/releases/mozilla-beta/raw-file/default/security/nss/lib/ckfw/builtins/certdata.txt', | ||
| 56 | 'release' => | ||
| 57 | 'http://hg.mozilla.org/releases/mozilla-release/raw-file/default/security/nss/lib/ckfw/builtins/certdata.txt', | ||
| 58 | ); | ||
| 59 | |||
| 60 | $opt_d = 'release'; | ||
| 61 | |||
| 62 | # If the OpenSSL commandline is not in search path you can configure it here! | ||
| 63 | my $openssl = 'openssl'; | ||
| 64 | |||
| 65 | my $version = '1.25'; | ||
| 66 | |||
| 67 | $opt_w = 76; # default base64 encoded lines length | ||
| 68 | |||
| 69 | # default cert types to include in the output (default is to include CAs which may issue SSL server certs) | ||
| 70 | my $default_mozilla_trust_purposes = "SERVER_AUTH"; | ||
| 71 | my $default_mozilla_trust_levels = "TRUSTED_DELEGATOR"; | ||
| 72 | $opt_p = $default_mozilla_trust_purposes . ":" . $default_mozilla_trust_levels; | ||
| 73 | |||
| 74 | my @valid_mozilla_trust_purposes = ( | ||
| 75 | "DIGITAL_SIGNATURE", | ||
| 76 | "NON_REPUDIATION", | ||
| 77 | "KEY_ENCIPHERMENT", | ||
| 78 | "DATA_ENCIPHERMENT", | ||
| 79 | "KEY_AGREEMENT", | ||
| 80 | "KEY_CERT_SIGN", | ||
| 81 | "CRL_SIGN", | ||
| 82 | "SERVER_AUTH", | ||
| 83 | "CLIENT_AUTH", | ||
| 84 | "CODE_SIGNING", | ||
| 85 | "EMAIL_PROTECTION", | ||
| 86 | "IPSEC_END_SYSTEM", | ||
| 87 | "IPSEC_TUNNEL", | ||
| 88 | "IPSEC_USER", | ||
| 89 | "TIME_STAMPING", | ||
| 90 | "STEP_UP_APPROVED" | ||
| 91 | ); | ||
| 92 | |||
| 93 | my @valid_mozilla_trust_levels = ( | ||
| 94 | "TRUSTED_DELEGATOR", # CAs | ||
| 95 | "NOT_TRUSTED", # Don't trust these certs. | ||
| 96 | "MUST_VERIFY_TRUST", # This explicitly tells us that it ISN'T a CA but is otherwise ok. In other words, this should tell the app to ignore any other sources that claim this is a CA. | ||
| 97 | "TRUSTED" # This cert is trusted, but only for itself and not for delegates (i.e. it is not a CA). | ||
| 98 | ); | ||
| 99 | |||
| 100 | my $default_signature_algorithms = $opt_s = "MD5"; | ||
| 101 | |||
| 102 | my @valid_signature_algorithms = ( | ||
| 103 | "MD5", | ||
| 104 | "SHA1", | ||
| 105 | "SHA256", | ||
| 106 | "SHA384", | ||
| 107 | "SHA512" | ||
| 108 | ); | ||
| 109 | |||
| 110 | $0 =~ s@.*(/|\\)@@; | ||
| 111 | $Getopt::Std::STANDARD_HELP_VERSION = 1; | ||
| 112 | getopts('bd:fhilnp:qs:tuvw:'); | ||
| 113 | |||
| 114 | if(!defined($opt_d)) { | ||
| 115 | # to make plain "-d" use not cause warnings, and actually still work | ||
| 116 | $opt_d = 'release'; | ||
| 117 | } | ||
| 118 | |||
| 119 | # Use predefined URL or else custom URL specified on command line. | ||
| 120 | my $url = ( defined( $urls{$opt_d} ) ) ? $urls{$opt_d} : $opt_d; | ||
| 121 | |||
| 122 | my $curl = `curl -V`; | ||
| 123 | |||
| 124 | if ($opt_i) { | ||
| 125 | print ("=" x 78 . "\n"); | ||
| 126 | print "Script Version : $version\n"; | ||
| 127 | print "Perl Version : $]\n"; | ||
| 128 | print "Operating System Name : $^O\n"; | ||
| 129 | print "Getopt::Std.pm Version : ${Getopt::Std::VERSION}\n"; | ||
| 130 | print "MIME::Base64.pm Version : ${MIME::Base64::VERSION}\n"; | ||
| 131 | print "LWP::UserAgent.pm Version : ${LWP::UserAgent::VERSION}\n"; | ||
| 132 | print "LWP.pm Version : ${LWP::VERSION}\n"; | ||
| 133 | print "Digest::SHA.pm Version : ${Digest::SHA::VERSION}\n" if ($Digest::SHA::VERSION); | ||
| 134 | print "Digest::SHA::PurePerl.pm Version : ${Digest::SHA::PurePerl::VERSION}\n" if ($Digest::SHA::PurePerl::VERSION); | ||
| 135 | print ("=" x 78 . "\n"); | ||
| 136 | } | ||
| 137 | |||
| 138 | sub warning_message() { | ||
| 139 | if ( $opt_d =~ m/^risk$/i ) { # Long Form Warning and Exit | ||
| 140 | print "Warning: Use of this script may pose some risk:\n"; | ||
| 141 | print "\n"; | ||
| 142 | print " 1) Using http is subject to man in the middle attack of certdata content\n"; | ||
| 143 | print " 2) Default to 'release', but more recent updates may be found in other trees\n"; | ||
| 144 | print " 3) certdata.txt file format may change, lag time to update this script\n"; | ||
| 145 | print " 4) Generally unwise to blindly trust CAs without manual review & verification\n"; | ||
| 146 | print " 5) Mozilla apps use additional security checks aren't represented in certdata\n"; | ||
| 147 | print " 6) Use of this script will make a security engineer grind his teeth and\n"; | ||
| 148 | print " swear at you. ;)\n"; | ||
| 149 | exit; | ||
| 150 | } else { # Short Form Warning | ||
| 151 | print "Warning: Use of this script may pose some risk, -d risk for more details.\n"; | ||
| 152 | } | ||
| 153 | } | ||
| 154 | |||
| 155 | sub HELP_MESSAGE() { | ||
| 156 | print "Usage:\t${0} [-b] [-d<certdata>] [-f] [-i] [-l] [-n] [-p<purposes:levels>] [-q] [-s<algorithms>] [-t] [-u] [-v] [-w<l>] [<outputfile>]\n"; | ||
| 157 | print "\t-b\tbackup an existing version of ca-bundle.crt\n"; | ||
| 158 | print "\t-d\tspecify Mozilla tree to pull certdata.txt or custom URL\n"; | ||
| 159 | print "\t\t Valid names are:\n"; | ||
| 160 | print "\t\t ", join( ", ", map { ( $_ =~ m/$opt_d/ ) ? "$_ (default)" : "$_" } sort keys %urls ), "\n"; | ||
| 161 | print "\t-f\tforce rebuild even if certdata.txt is current\n"; | ||
| 162 | print "\t-i\tprint version info about used modules\n"; | ||
| 163 | print "\t-l\tprint license info about certdata.txt\n"; | ||
| 164 | print "\t-n\tno download of certdata.txt (to use existing)\n"; | ||
| 165 | print wrap("\t","\t\t", "-p\tlist of Mozilla trust purposes and levels for certificates to include in output. Takes the form of a comma separated list of purposes, a colon, and a comma separated list of levels. (default: $default_mozilla_trust_purposes:$default_mozilla_trust_levels)"), "\n"; | ||
| 166 | print "\t\t Valid purposes are:\n"; | ||
| 167 | print wrap("\t\t ","\t\t ", join( ", ", "ALL", @valid_mozilla_trust_purposes ) ), "\n"; | ||
| 168 | print "\t\t Valid levels are:\n"; | ||
| 169 | print wrap("\t\t ","\t\t ", join( ", ", "ALL", @valid_mozilla_trust_levels ) ), "\n"; | ||
| 170 | print "\t-q\tbe really quiet (no progress output at all)\n"; | ||
| 171 | print wrap("\t","\t\t", "-s\tcomma separated list of certificate signatures/hashes to output in plain text mode. (default: $default_signature_algorithms)\n"); | ||
| 172 | print "\t\t Valid signature algorithms are:\n"; | ||
| 173 | print wrap("\t\t ","\t\t ", join( ", ", "ALL", @valid_signature_algorithms ) ), "\n"; | ||
| 174 | print "\t-t\tinclude plain text listing of certificates\n"; | ||
| 175 | print "\t-u\tunlink (remove) certdata.txt after processing\n"; | ||
| 176 | print "\t-v\tbe verbose and print out processed CAs\n"; | ||
| 177 | print "\t-w <l>\twrap base64 output lines after <l> chars (default: ${opt_w})\n"; | ||
| 178 | exit; | ||
| 179 | } | ||
| 180 | |||
| 181 | sub VERSION_MESSAGE() { | ||
| 182 | print "${0} version ${version} running Perl ${]} on ${^O}\n"; | ||
| 183 | } | ||
| 184 | |||
| 185 | warning_message() unless ($opt_q || $url =~ m/^(ht|f)tps:/i ); | ||
| 186 | HELP_MESSAGE() if ($opt_h); | ||
| 187 | |||
| 188 | sub report($@) { | ||
| 189 | my $output = shift; | ||
| 190 | |||
| 191 | print STDERR $output . "\n" unless $opt_q; | ||
| 192 | } | ||
| 193 | |||
| 194 | sub is_in_list($@) { | ||
| 195 | my $target = shift; | ||
| 196 | |||
| 197 | return defined(List::Util::first { $target eq $_ } @_); | ||
| 198 | } | ||
| 199 | |||
| 200 | # Parses $param_string as a case insensitive comma separated list with optional whitespace | ||
| 201 | # validates that only allowed parameters are supplied | ||
| 202 | sub parse_csv_param($$@) { | ||
| 203 | my $description = shift; | ||
| 204 | my $param_string = shift; | ||
| 205 | my @valid_values = @_; | ||
| 206 | |||
| 207 | my @values = map { | ||
| 208 | s/^\s+//; # strip leading spaces | ||
| 209 | s/\s+$//; # strip trailing spaces | ||
| 210 | uc $_ # return the modified string as upper case | ||
| 211 | } split( ',', $param_string ); | ||
| 212 | |||
| 213 | # Find all values which are not in the list of valid values or "ALL" | ||
| 214 | my @invalid = grep { !is_in_list($_,"ALL",@valid_values) } @values; | ||
| 215 | |||
| 216 | if ( scalar(@invalid) > 0 ) { | ||
| 217 | # Tell the user which parameters were invalid and print the standard help message which will exit | ||
| 218 | print "Error: Invalid ", $description, scalar(@invalid) == 1 ? ": " : "s: ", join( ", ", map { "\"$_\"" } @invalid ), "\n"; | ||
| 219 | HELP_MESSAGE(); | ||
| 220 | } | ||
| 221 | |||
| 222 | @values = @valid_values if ( is_in_list("ALL",@values) ); | ||
| 223 | |||
| 224 | return @values; | ||
| 225 | } | ||
| 226 | |||
| 227 | sub sha1 { | ||
| 228 | my $result; | ||
| 229 | if ($Digest::SHA::VERSION || $Digest::SHA::PurePerl::VERSION) { | ||
| 230 | open(FILE, $_[0]) or die "Can't open '$_[0]': $!"; | ||
| 231 | binmode(FILE); | ||
| 232 | $result = $MOD_SHA->new(1)->addfile(*FILE)->hexdigest; | ||
| 233 | close(FILE); | ||
| 234 | } else { | ||
| 235 | # Use OpenSSL command if Perl Digest::SHA modules not available | ||
| 236 | $result = (split(/ |\r|\n/,`$openssl dgst -sha1 $_[0]`))[1]; | ||
| 237 | } | ||
| 238 | return $result; | ||
| 239 | } | ||
| 240 | |||
| 241 | |||
| 242 | sub oldsha1 { | ||
| 243 | my $sha1 = ""; | ||
| 244 | open(C, "<$_[0]") || return 0; | ||
| 245 | while(<C>) { | ||
| 246 | chomp; | ||
| 247 | if($_ =~ /^\#\# SHA1: (.*)/) { | ||
| 248 | $sha1 = $1; | ||
| 249 | last; | ||
| 250 | } | ||
| 251 | } | ||
| 252 | close(C); | ||
| 253 | return $sha1; | ||
| 254 | } | ||
| 255 | |||
| 256 | if ( $opt_p !~ m/:/ ) { | ||
| 257 | print "Error: Mozilla trust identifier list must include both purposes and levels\n"; | ||
| 258 | HELP_MESSAGE(); | ||
| 259 | } | ||
| 260 | |||
| 261 | (my $included_mozilla_trust_purposes_string, my $included_mozilla_trust_levels_string) = split( ':', $opt_p ); | ||
| 262 | my @included_mozilla_trust_purposes = parse_csv_param( "trust purpose", $included_mozilla_trust_purposes_string, @valid_mozilla_trust_purposes ); | ||
| 263 | my @included_mozilla_trust_levels = parse_csv_param( "trust level", $included_mozilla_trust_levels_string, @valid_mozilla_trust_levels ); | ||
| 264 | |||
| 265 | my @included_signature_algorithms = parse_csv_param( "signature algorithm", $opt_s, @valid_signature_algorithms ); | ||
| 266 | |||
| 267 | sub should_output_cert(%) { | ||
| 268 | my %trust_purposes_by_level = @_; | ||
| 269 | |||
| 270 | foreach my $level (@included_mozilla_trust_levels) { | ||
| 271 | # for each level we want to output, see if any of our desired purposes are included | ||
| 272 | return 1 if ( defined( List::Util::first { is_in_list( $_, @included_mozilla_trust_purposes ) } @{$trust_purposes_by_level{$level}} ) ); | ||
| 273 | } | ||
| 274 | |||
| 275 | return 0; | ||
| 276 | } | ||
| 277 | |||
| 278 | my $crt = $ARGV[0] || 'ca-bundle.crt'; | ||
| 279 | (my $txt = $url) =~ s@(.*/|\?.*)@@g; | ||
| 280 | |||
| 281 | my $stdout = $crt eq '-'; | ||
| 282 | my $resp; | ||
| 283 | my $fetched; | ||
| 284 | |||
| 285 | my $oldsha1 = oldsha1($crt); | ||
| 286 | |||
| 287 | report "SHA1 of old file: $oldsha1"; | ||
| 288 | |||
| 289 | report "Downloading '$txt' ..."; | ||
| 290 | |||
| 291 | if($curl && !$opt_n) { | ||
| 292 | my $https = $url; | ||
| 293 | $https =~ s/^http:/https:/; | ||
| 294 | report "Get certdata over HTTPS with curl!"; | ||
| 295 | my $quiet = $opt_q ? "-s" : ""; | ||
| 296 | my @out = `curl -w %{response_code} $quiet -O $https`; | ||
| 297 | if(@out && $out[0] == 200) { | ||
| 298 | $fetched = 1; | ||
| 299 | } else { | ||
| 300 | report "Failed downloading HTTPS with curl, trying HTTP with LWP"; | ||
| 301 | } | ||
| 302 | } | ||
| 303 | |||
| 304 | unless ($fetched || ($opt_n and -e $txt)) { | ||
| 305 | my $ua = new LWP::UserAgent(agent => "$0/$version"); | ||
| 306 | $ua->env_proxy(); | ||
| 307 | $resp = $ua->mirror($url, $txt); | ||
| 308 | if ($resp && $resp->code eq '304') { | ||
| 309 | report "Not modified"; | ||
| 310 | exit 0 if -e $crt && !$opt_f; | ||
| 311 | } else { | ||
| 312 | $fetched = 1; | ||
| 313 | } | ||
| 314 | if( !$resp || $resp->code !~ /^(?:200|304)$/ ) { | ||
| 315 | report "Unable to download latest data: " | ||
| 316 | . ($resp? $resp->code . ' - ' . $resp->message : "LWP failed"); | ||
| 317 | exit 1 if -e $crt || ! -r $txt; | ||
| 318 | } | ||
| 319 | } | ||
| 320 | |||
| 321 | my $filedate = $resp ? $resp->last_modified : (stat($txt))[9]; | ||
| 322 | my $datesrc = "as of"; | ||
| 323 | if(!$filedate) { | ||
| 324 | # mxr.mozilla.org gave us a time, hg.mozilla.org does not! | ||
| 325 | $filedate = time(); | ||
| 326 | $datesrc="downloaded on"; | ||
| 327 | } | ||
| 328 | |||
| 329 | # get the hash from the download file | ||
| 330 | my $newsha1= sha1($txt); | ||
| 331 | |||
| 332 | if(!$opt_f && $oldsha1 eq $newsha1) { | ||
| 333 | report "Downloaded file identical to previous run\'s source file. Exiting"; | ||
| 334 | exit; | ||
| 335 | } | ||
| 336 | |||
| 337 | report "SHA1 of new file: $newsha1"; | ||
| 338 | |||
| 339 | my $currentdate = scalar gmtime($filedate); | ||
| 340 | |||
| 341 | my $format = $opt_t ? "plain text and " : ""; | ||
| 342 | if( $stdout ) { | ||
| 343 | open(CRT, '> -') or die "Couldn't open STDOUT: $!\n"; | ||
| 344 | } else { | ||
| 345 | open(CRT,">$crt.~") or die "Couldn't open $crt.~: $!\n"; | ||
| 346 | } | ||
| 347 | print CRT <<EOT; | ||
| 348 | ## | ||
| 349 | ## Bundle of CA Root Certificates | ||
| 350 | ## | ||
| 351 | ## Certificate data from Mozilla ${datesrc}: ${currentdate} | ||
| 352 | ## | ||
| 353 | ## This is a bundle of X.509 certificates of public Certificate Authorities | ||
| 354 | ## (CA). These were automatically extracted from Mozilla's root certificates | ||
| 355 | ## file (certdata.txt). This file can be found in the mozilla source tree: | ||
| 356 | ## ${url} | ||
| 357 | ## | ||
| 358 | ## It contains the certificates in ${format}PEM format and therefore | ||
| 359 | ## can be directly used with curl / libcurl / php_curl, or with | ||
| 360 | ## an Apache+mod_ssl webserver for SSL client authentication. | ||
| 361 | ## Just configure this file as the SSLCACertificateFile. | ||
| 362 | ## | ||
| 363 | ## Conversion done with mk-ca-bundle.pl version $version. | ||
| 364 | ## SHA1: $newsha1 | ||
| 365 | ## | ||
| 366 | |||
| 367 | EOT | ||
| 368 | |||
| 369 | report "Processing '$txt' ..."; | ||
| 370 | my $caname; | ||
| 371 | my $certnum = 0; | ||
| 372 | my $skipnum = 0; | ||
| 373 | my $start_of_cert = 0; | ||
| 374 | |||
| 375 | open(TXT,"$txt") or die "Couldn't open $txt: $!\n"; | ||
| 376 | while (<TXT>) { | ||
| 377 | if (/\*\*\*\*\* BEGIN LICENSE BLOCK \*\*\*\*\*/) { | ||
| 378 | print CRT; | ||
| 379 | print if ($opt_l); | ||
| 380 | while (<TXT>) { | ||
| 381 | print CRT; | ||
| 382 | print if ($opt_l); | ||
| 383 | last if (/\*\*\*\*\* END LICENSE BLOCK \*\*\*\*\*/); | ||
| 384 | } | ||
| 385 | } | ||
| 386 | next if /^#|^\s*$/; | ||
| 387 | chomp; | ||
| 388 | if (/^CVS_ID\s+\"(.*)\"/) { | ||
| 389 | print CRT "# $1\n"; | ||
| 390 | } | ||
| 391 | |||
| 392 | # this is a match for the start of a certificate | ||
| 393 | if (/^CKA_CLASS CK_OBJECT_CLASS CKO_CERTIFICATE/) { | ||
| 394 | $start_of_cert = 1 | ||
| 395 | } | ||
| 396 | if ($start_of_cert && /^CKA_LABEL UTF8 \"(.*)\"/) { | ||
| 397 | $caname = $1; | ||
| 398 | } | ||
| 399 | my %trust_purposes_by_level; | ||
| 400 | if ($start_of_cert && /^CKA_VALUE MULTILINE_OCTAL/) { | ||
| 401 | my $data; | ||
| 402 | while (<TXT>) { | ||
| 403 | last if (/^END/); | ||
| 404 | chomp; | ||
| 405 | my @octets = split(/\\/); | ||
| 406 | shift @octets; | ||
| 407 | for (@octets) { | ||
| 408 | $data .= chr(oct); | ||
| 409 | } | ||
| 410 | } | ||
| 411 | # scan forwards until the trust part | ||
| 412 | while (<TXT>) { | ||
| 413 | last if (/^CKA_CLASS CK_OBJECT_CLASS CKO_NSS_TRUST/); | ||
| 414 | chomp; | ||
| 415 | } | ||
| 416 | # now scan the trust part to determine how we should trust this cert | ||
| 417 | while (<TXT>) { | ||
| 418 | last if (/^#/); | ||
| 419 | if (/^CKA_TRUST_([A-Z_]+)\s+CK_TRUST\s+CKT_NSS_([A-Z_]+)\s*$/) { | ||
| 420 | if ( !is_in_list($1,@valid_mozilla_trust_purposes) ) { | ||
| 421 | report "Warning: Unrecognized trust purpose for cert: $caname. Trust purpose: $1. Trust Level: $2"; | ||
| 422 | } elsif ( !is_in_list($2,@valid_mozilla_trust_levels) ) { | ||
| 423 | report "Warning: Unrecognized trust level for cert: $caname. Trust purpose: $1. Trust Level: $2"; | ||
| 424 | } else { | ||
| 425 | push @{$trust_purposes_by_level{$2}}, $1; | ||
| 426 | } | ||
| 427 | } | ||
| 428 | } | ||
| 429 | |||
| 430 | if ( !should_output_cert(%trust_purposes_by_level) ) { | ||
| 431 | $skipnum ++; | ||
| 432 | } else { | ||
| 433 | my $encoded = MIME::Base64::encode_base64($data, ''); | ||
| 434 | $encoded =~ s/(.{1,${opt_w}})/$1\n/g; | ||
| 435 | my $pem = "-----BEGIN CERTIFICATE-----\n" | ||
| 436 | . $encoded | ||
| 437 | . "-----END CERTIFICATE-----\n"; | ||
| 438 | print CRT "\n$caname\n"; | ||
| 439 | |||
| 440 | my $maxStringLength = length($caname); | ||
| 441 | if ($opt_t) { | ||
| 442 | foreach my $key (keys %trust_purposes_by_level) { | ||
| 443 | my $string = $key . ": " . join(", ", @{$trust_purposes_by_level{$key}}); | ||
| 444 | $maxStringLength = List::Util::max( length($string), $maxStringLength ); | ||
| 445 | print CRT $string . "\n"; | ||
| 446 | } | ||
| 447 | } | ||
| 448 | print CRT ("=" x $maxStringLength . "\n"); | ||
| 449 | if (!$opt_t) { | ||
| 450 | print CRT $pem; | ||
| 451 | } else { | ||
| 452 | my $pipe = ""; | ||
| 453 | foreach my $hash (@included_signature_algorithms) { | ||
| 454 | $pipe = "|$openssl x509 -" . $hash . " -fingerprint -noout -inform PEM"; | ||
| 455 | if (!$stdout) { | ||
| 456 | $pipe .= " >> $crt.~"; | ||
| 457 | close(CRT) or die "Couldn't close $crt.~: $!"; | ||
| 458 | } | ||
| 459 | open(TMP, $pipe) or die "Couldn't open openssl pipe: $!"; | ||
| 460 | print TMP $pem; | ||
| 461 | close(TMP) or die "Couldn't close openssl pipe: $!"; | ||
| 462 | if (!$stdout) { | ||
| 463 | open(CRT, ">>$crt.~") or die "Couldn't open $crt.~: $!"; | ||
| 464 | } | ||
| 465 | } | ||
| 466 | $pipe = "|$openssl x509 -text -inform PEM"; | ||
| 467 | if (!$stdout) { | ||
| 468 | $pipe .= " >> $crt.~"; | ||
| 469 | close(CRT) or die "Couldn't close $crt.~: $!"; | ||
| 470 | } | ||
| 471 | open(TMP, $pipe) or die "Couldn't open openssl pipe: $!"; | ||
| 472 | print TMP $pem; | ||
| 473 | close(TMP) or die "Couldn't close openssl pipe: $!"; | ||
| 474 | if (!$stdout) { | ||
| 475 | open(CRT, ">>$crt.~") or die "Couldn't open $crt.~: $!"; | ||
| 476 | } | ||
| 477 | } | ||
| 478 | report "Parsing: $caname" if ($opt_v); | ||
| 479 | $certnum ++; | ||
| 480 | $start_of_cert = 0; | ||
| 481 | } | ||
| 482 | } | ||
| 483 | } | ||
| 484 | close(TXT) or die "Couldn't close $txt: $!\n"; | ||
| 485 | close(CRT) or die "Couldn't close $crt.~: $!\n"; | ||
| 486 | unless( $stdout ) { | ||
| 487 | if ($opt_b && -e $crt) { | ||
| 488 | my $bk = 1; | ||
| 489 | while (-e "$crt.~${bk}~") { | ||
| 490 | $bk++; | ||
| 491 | } | ||
| 492 | rename $crt, "$crt.~${bk}~" or die "Failed to create backup $crt.~$bk}~: $!\n"; | ||
| 493 | } elsif( -e $crt ) { | ||
| 494 | unlink( $crt ) or die "Failed to remove $crt: $!\n"; | ||
| 495 | } | ||
| 496 | rename "$crt.~", $crt or die "Failed to rename $crt.~ to $crt: $!\n"; | ||
| 497 | } | ||
| 498 | unlink $txt if ($opt_u); | ||
| 499 | report "Done ($certnum CA certs processed, $skipnum skipped)."; |