File Coverage

blib/lib/PayProp/API/Public/Client/Role/Storage.pm

Criterion	Covered	Total	%
statement	15	35	42.8
branch	1	8	12.5
condition	1	5	20.0
subroutine	5	15	33.3
pod	4	4	100.0
total	26	67	38.8

package PayProp::API::Public::Client::Role::Storage;

use strict;
use warnings;

use Mouse::Role;
with qw/ PayProp::API::Public::Client::Role::Encrypt /;

use PayProp::API::Public::Client::Exception::Storage;

has cache_prefix => (
	is => 'ro',
	isa => 'Str',
	lazy => 1,
	default => sub { 'PayPropAPIToken_' }
);

has cache_ttl_in_seconds => (
	is => 'ro',
	isa => 'Int',
	lazy => 1,
	default => sub { 3600 * 12 } # TTL: 12 hours
);

has throw_on_storage_unavailable => ( is => 'ro', isa => 'Bool', lazy => 1, default => sub { 0 } );

requires qw/
	_set_p
	_get_p
	_ping_p
	_delete_p
/;

sub ping_p {
	my ( $self ) = @_;

	return $self
		->_ping_p
		->catch( sub { $self->_handle_exception( @_ ) } )
	;
}

sub set_p {
	my ( $self, $key, $token ) = @_;

	die 'key and token are required for set_p' unless $key && $token;

	return $self
		->encrypt_hex_p( $token )
		->then( sub {
			my ( $encrypted_token ) = @_;

			return $self->_set_p( $key, $encrypted_token );
		} )
		->catch( sub { $self->_handle_exception( @_ ) } )
	;
}

sub get_p {
	my ( $self, $key ) = @_;

	die 'key is required for get_p' unless $key;

	return $self
		->_get_p( $key )
		->then( sub { $self->decrypt_hex_p( @_ ) } )
		->catch( sub { $self->_handle_exception( @_ ) } )
	;
}

sub delete_p {
	my ( $self, $key ) = @_;

	die 'key is required for delete_p' unless $key;

	return $self
		->_delete_p( $key )
		->catch( sub { $self->_handle_exception( @_ ) } )
	;
}

sub _handle_exception {
	my ( $self, $exception ) = @_;

	$exception //= 'UNKKNOWN STORAGE ERROR';

	# stop promise chain
	PayProp::API::Public::Client::Exception::Storage->throw("$exception")
		if $self->throw_on_storage_unavailable
	;

	warn "$exception";

	return undef; # continue promise chain
}

1;

__END__