File Coverage

blib/lib/PayProp/API/Public/Client/Exception/Base.pm

Criterion	Covered	Total	%
statement	30	37	81.0
branch	6	6	100.0
condition	8	12	66.6
subroutine	9	11	81.8
pod	7	7	100.0
total	60	73	82.1

package PayProp::API::Public::Client::Exception::Base;

use strict;
use warnings;
use parent qw/ Exception::Class::Base /;

use Module::Load qw//;


sub error_class { undef }

sub error_fields { undef }

sub errors { shift->{errors} }

sub status_code { shift->{status_code} }

sub Fields { qw/ status_code errors / } # for Exception::Class::Base

sub throw {
	my ( $self, @args ) = @_;

	my $args_size = scalar @args;

	die 'wrong number of args for throw - expected either an error message or pairs'
		if $args_size > 1 && $args_size % 2
	;

	# allow ->throw('my error message') that would otherwise cause args to be ( 'my error message' => undef )
	# for e.g. PayProp::API::Public::Client::Exception::Connection
	my %args = $args_size == 1 ? ( message => "$args[0]" ) : @args;

	# for e.g. PayProp::API::Public::Client::Exception::Authorization
	if ( $self->error_class && $self->error_fields ) {
		my $error_class = $self->error_class;
		Module::Load::load( $error_class );

		$args{errors} = [
			map {
				my $error_ref = $_;

				$error_class->new(
					(
						map {
							my $value = $error_ref->{ $_ } // '';
							$_ => "$value";
						} $self->error_fields
					)
				)
			} @{ $args{errors} // [] }
		];
	}

	$self->SUPER::throw( %args );
}

sub to_hashref {
	my ( $self ) = @_;

	return {
		class => ref( $self ),
		message => $self->{message},
		status_code => $self->{status_code},
		errors => [
			map {
				my $error = $_;
				+{
					class => ref( $error ),
					fields => {
						map { $_ => $error->{ $_ } } qw/ path code message /
					},
				}
			} @{ $self->{errors} // [] }
		],
	};
}

1;

__END__