File Coverage

blib/lib/PayProp/API/Public/Client/Authorization/Base.pm

Criterion	Covered	Total	%
statement	16	30	53.3
branch	1	6	16.6
condition			n/a
subroutine	6	9	66.6
pod	1	2	50.0
total	24	47	51.0

package PayProp::API::Public::Client::Authorization::Base;

use strict;
use warnings;

use Mouse;
with qw/ PayProp::API::Public::Client::Role::Attribute::Token /;
with qw/ PayProp::API::Public::Client::Role::Attribute::Storage /;

use Mojo::Promise;


has is_token_from_storage => ( is => 'rw', isa => 'Bool' );

sub token_request_p {
	my ( $self ) = @_;

	$self->is_token_from_storage( 0 );

	return $self->_token_request_p unless $self->has_storage;

	return $self
		->storage
		->get_p( $self->storage_key )
		->then( sub {
			my ( $token ) = @_;

			if ( $token ) {
				$self->is_token_from_storage( 1 );

				return {
					token => $token,
					token_type => $self->token_type,
				};
			}

			return $self
				->_token_request_p
				->then( sub {
					my ( $token_info ) = @_;

					return $self
						->storage
						->set_p( $self->storage_key, $token_info->{token} )
						->then( sub { $token_info } )
					;
				} )
			;
		} )
	;
}

sub remove_token_from_storage_p {
	my ( $self ) = @_;

	$self->is_token_from_storage( 0 );

	return Mojo::Promise
		->new( sub {
			my ( $resolve ) = @_;

			return $resolve->(
				! $self->has_storage
					? 1
					: $self->storage->delete_p( $self->storage_key )
			);
		} )
	;
}

sub _token_request_p { die '_token_request_p not implemented' }

__PACKAGE__->meta->make_immutable;

__END__