File Coverage

blib/lib/Path/Tiny/Archive/Zip.pm

Criterion	Covered	Total	%
statement	35	40	87.5
branch	11	20	55.0
condition			n/a
subroutine	9	9	100.0
pod	2	2	100.0
total	57	71	80.2

package Path::Tiny::Archive::Zip;

# ABSTRACT: Zip/unzip add-on for file path utility

use strict;
use warnings;

use Archive::Zip ();
use Exporter qw( import );
use Path::Tiny qw( path );


our $VERSION = '0.004';

our %EXPORT_TAGS = ( const =>[qw(
    COMPRESSION_DEFAULT
    COMPRESSION_NONE
    COMPRESSION_FASTEST
    COMPRESSION_BEST
)] );
our @EXPORT_OK = @{ $EXPORT_TAGS{const} };


BEGIN {
    push(@Path::Tiny::ISA, __PACKAGE__);
}

use constant {
    COMPRESSION_DEFAULT => Archive::Zip::COMPRESSION_LEVEL_DEFAULT,           # 6
    COMPRESSION_NONE    => Archive::Zip::COMPRESSION_LEVEL_NONE,              # 0
    COMPRESSION_FASTEST => Archive::Zip::COMPRESSION_LEVEL_FASTEST,           # 1
    COMPRESSION_BEST    => Archive::Zip::COMPRESSION_LEVEL_BEST_COMPRESSION,  # 9
};


sub zip {
    my ($self, $dest, $level) = @_;

    my $zip = Archive::Zip->new;

    if ($self->is_file) {
        $zip->addFile($self->stringify(), $self->basename, defined $level ? $level : ());
    }
    elsif ($self->is_dir) {
        $zip->addTree($self->stringify(), '', undef, defined $level ? $level : ());
    }
    else {
        return;
    }

    $dest = path($dest);

    unless ($zip->writeToFileNamed($dest->stringify()) == Archive::Zip::AZ_OK) {
        return;
    }

    return $dest;
}


sub unzip {
    my ($self, $dest) = @_;

    my $zip = Archive::Zip->new();

    unless ($zip->read($self->stringify()) == Archive::Zip::AZ_OK) {
        return;
    }

    $dest = path($dest);
    if ($dest->exists) {
        return unless $dest->is_dir;
    }
    else {
        $dest->mkpath() or return;
    }

    unless ($zip->extractTree(undef, $dest->stringify()) == Archive::Zip::AZ_OK) {
        return;
    }

    return $dest;
}


1;

__END__