File Coverage

blib/lib/Path/Naive.pm

Criterion	Covered	Total	%
statement	46	46	100.0
branch	32	34	94.1
condition	26	30	86.6
subroutine	11	11	100.0
pod	7	7	100.0
total	122	128	95.3

package Path::Naive;

use 5.010001;
use strict;
use warnings;

our $VERSION = '0.040'; # VERSION

use Exporter;
our @ISA = qw(Exporter);
our @EXPORT_OK = qw(
                       split_path
                       normalize_path
                       is_abs_path
                       is_rel_path
                       concat_path
                       concat_path_n
                       abs_path
               );

sub split_path {
    die "Please specify path" unless defined($_[0]) && length($_[0]);
    grep {length} split qr!/+!, $_[0];
}

sub normalize_path {
    my @d0 = split_path $_[0];
    my $abs = $_[0] =~ m!\A/!;
    my @d;
    while (@d0) {
        my $d = shift @d0;
        next if $d eq '.' && (@d || @d0 || $abs);
        do { pop @d; next } if $d eq '..' &&
            (@d>1 && $d[-1] ne '..' ||
                 @d==1 && $d[-1] ne '..' && $d[-1] ne '.' && @d0 ||
                     $abs);
        push @d, $d;
    }
    if (wantarray) {
        @d;
    } else {
        ($abs ? "/" : "") . join("/", @d);
    }
}

sub is_abs_path {
    die "Please specify path" unless defined($_[0]) && length($_[0]);
    $_[0] =~ m!\A/! ? 1:0;
}

sub is_rel_path {
    die "Please specify path" unless defined($_[0]) && length($_[0]);
    $_[0] =~ m!\A/! ? 0:1;
}

sub concat_path {
    die "Please specify at least two paths" unless @_ > 1;
    my $i = 0;
    my $res = $_[0];
    for (@_) {
        die "Please specify path (#$i)" unless defined && length;
        next unless $i++;
        if (m!\A/!) {
            $res = $_;
        } else {
            $res .= ($res =~ m!/\z! ? "" : "/") . $_;
        }
    }
    $res;
}

sub concat_path_n {
    normalize_path(concat_path(@_));
}

sub abs_path {
    die "Please specify path" unless defined($_[0]) && length($_[0]);
    die "Please specify base" unless defined($_[1]) && length($_[1]);
    die "base must be absolute" unless is_abs_path($_[1]);
    concat_path_n($_[1], $_[0]);
}

1;
# ABSTRACT: Yet another abstract, Unix-like path manipulation routines

__END__