File Coverage

blib/lib/Parse/Crontab.pm

Criterion	Covered	Total	%
statement	73	75	97.3
branch	19	22	86.3
condition	3	3	100.0
subroutine	18	18	100.0
pod	3	5	60.0
total	116	123	94.3

package Parse::Crontab;
use 5.008_001;
use strict;
use warnings;
use Carp;

our $VERSION = '0.05';

use Mouse;
use Path::Class;

use Parse::Crontab::Entry::Env;
use Parse::Crontab::Entry::Job;
use Parse::Crontab::Entry::Comment;
use Parse::Crontab::Entry::Empty;
use Parse::Crontab::Entry::Error;

has file => (
    is => 'ro',
);

has content => (
    is   => 'ro',
    isa  => 'Str',
    lazy => 1,
    default => sub {
        my $self = shift;
        croak 'Attribute file or content is required!' unless defined $self->file;
        Path::Class::file($self->file)->slurp;
    },
);

has entries => (
    is => 'rw',
    isa => 'ArrayRef[Parse::Crontab::Entry]',
    default => sub {[]},
    auto_deref => 1,
);

has env => (
    is => 'rw',
    isa => 'HashRef',
    default => sub {{}},
);

has verbose => (
    is => 'rw',
    isa => 'Bool',
    default => 1,
);

has has_user_field => (
    is => 'rw',
    isa => 'Bool',
    default => undef,
);

no Mouse;

sub BUILD {
    my $self = shift;

    my $line_number = 1;
    for my $line (split /\r?\n/, $self->content) {
        my $entry_class = 'Parse::Crontab::Entry::'. $self->_decide_entry_class($line);
        my $entry = $entry_class->new(line => $line, line_number => $line_number, has_user_field => $self->has_user_field);
        $line_number++;

        if ($entry_class eq 'Parse::Crontab::Entry::Env' && !$entry->is_error) {
            # overwritten if same key already exists
            $self->env->{$entry->key} = $entry->value;
        }
        push @{$self->entries}, $entry;
    }

    if ($self->verbose) {
        my $error = $self->error_messages;
        warn $error if $error;
        my $warn  = $self->warning_messages;
        warn $warn  if $warn;
    }
}

sub is_valid {
    my $self = shift;

    for my $entry ($self->entries) {
        return () if $entry->is_error;
    }
    1;
}

sub error_messages {
    my $self = shift;
    my @errors;
    for my $entry ($self->entries) {
        push @errors, $entry->error_message if $entry->is_error;
    }
    join "\n", @errors;
}

sub warning_messages {
    my $self = shift;
    my @errors;
    for my $entry ($self->entries) {
        push @errors, $entry->warning_message if $entry->has_warnings;
    }
    join "\n", @errors;
}

sub jobs {
    my $self = shift;
    grep {$_->isa('Parse::Crontab::Entry::Job')} $self->entries;
}

sub _decide_entry_class {
    my ($self, $line) = @_;

    if ($line =~ /^#/) {
        'Comment';
    }
    elsif ($line =~ /^\s*$/) {
        'Empty';
    }
    elsif ($line =~ /^(?:@|\*|[0-9])/) {
        'Job';
    }
    elsif ($line =~ /=/) {
        'Env';
    }
    else {
        'Error';
    }
}

__PACKAGE__->meta->make_immutable;
__END__