File Coverage

blib/lib/Parcel/Track.pm

Criterion	Covered	Total	%
statement	57	57	100.0
branch	20	28	71.4
condition	15	18	83.3
subroutine	11	11	100.0
pod	1	2	50.0
total	104	116	89.6

package Parcel::Track;
# ABSTRACT: Driver-based API for tracking parcel

use Moo;
use Types::Standard qw( Object );

use Carp;
use Module::Runtime;
use Params::Util 0.14 ();
use Try::Tiny;

our $VERSION = '0.005';

has driver => (
    is      => 'ro',
    isa     => Object,
    handles => [qw( id uri )],
);

sub BUILDARGS {
    my ( $class, $driver_class, $id, @args ) = @_;

    unless ( defined $driver_class && !ref $driver_class && length $driver_class ) {
        Carp::croak("Did not provide a Parcel::Track driver name");
    }
    unless ( Params::Util::_CLASS($driver_class) ) {
        Carp::croak("Not a valid Parcel::Track driver name");
    }

    unless ( defined $id && !ref $id && length $id ) {
        Carp::croak("Did not provide a Parcel::Track tracking number");
    }

    my $driver_name = $driver_class;
    $driver_class = "Parcel::Track::$driver_class";
    try {
        Module::Runtime::require_module($driver_class);
    }
    catch {
        if (m/^Can't locate /) {
            # Driver does not exist
            Carp::croak("Parcel::Track driver $driver_name does not exist, or is not installed");
        }
        else {
            # Fatal error within the driver itself
            # Pass on without change
            Carp::croak($_);
        }
    };
    unless ( $driver_class->can('new') ) {
        Carp::croak("$driver_class does not have new method");
    }
    my $driver = $driver_class->new(
        id => $id,
        $class->_PRIVATE(@args),
    );
    unless ( $driver->can('does') && $driver->does('Parcel::Track::Role::Base') ) {
        Carp::croak("$driver_class does not have Parcel::Track::Role::Base role");
    }

    return +{ driver => $driver };
}

sub track {
    my $self = shift;

    my $rv = $self->driver->track;
    Carp::croak("Driver did not return a result")
        unless Params::Util::_HASH($rv);
    Carp::croak("Driver returned an invalid \$result->{from}")
        unless Params::Util::_SCALAR0( \$rv->{from} );
    Carp::croak("Driver returned an invalid \$result->{to}")
        unless Params::Util::_SCALAR0( \$rv->{to} );
    Carp::croak("Driver returned an invalid \$result->{result}")
        unless Params::Util::_SCALAR0( \$rv->{result} );
    Carp::croak("Driver returned an invalid \$result->{descs}")
        unless Params::Util::_ARRAY0( $rv->{descs} );
    Carp::croak("Driver returned an invalid \$result->{htmls}")
        unless Params::Util::_ARRAY0( $rv->{htmls} );

    return $rv;
}

# Filter params for only the private params
sub _PRIVATE {
    my $class  = ref $_[0] ? ref shift : shift;
    my @input  = @_;
    my @output = ();
    while (@input) {
        my $key   = shift @input;
        my $value = shift @input;
        if ( Params::Util::_STRING($key) and $key =~ /^_/ ) {
            $key =~ s/^_//;
            push @output, $key, $value;
        }
    }
    return @output;
}

1;

#
# This file is part of Parcel-Track
#
# This software is copyright (c) 2015 by Keedi Kim.
#
# This is free software; you can redistribute it and/or modify it under
# the same terms as the Perl 5 programming language system itself.
#

__END__