File Coverage

blib/lib/PYX/Optimization.pm

Criterion	Covered	Total	%
statement	65	65	100.0
branch	4	4	100.0
condition			n/a
subroutine	14	14	100.0
pod	4	4	100.0
total	87	87	100.0

package PYX::Optimization;

use strict;
use warnings;

use Class::Utils qw(set_params);
use Encode;
use Error::Pure qw(err);
use PYX qw(char comment);
use PYX::Parser;
use PYX::Utils;

our $VERSION = 0.04;

# Constructor.
sub new {
	my ($class, @params) = @_;
	my $self = bless {}, $class;

	# Output encoding.
	$self->{'output_encoding'} = 'utf-8';

	# Output handler.
	$self->{'output_handler'} = \*STDOUT;

	# Process params.
	set_params($self, @params);

	# PYX::Parser object.
	$self->{'pyx_parser'} = PYX::Parser->new(
		'output_encoding' => $self->{'output_encoding'},
		'output_handler' => $self->{'output_handler'},
		'output_rewrite' => 1,
		'callbacks' => {
			'data' => \&_data,
			'comment' => \&_comment,
		},
		'non_parser_options' => {
			'output_encoding' => $self->{'output_encoding'},
		},
	);

	# Object.
	return $self;
}

# Parse pyx text or array of pyx text.
sub parse {
	my ($self, $pyx, $out) = @_;

	$self->{'pyx_parser'}->parse($pyx, $out);

	return;
}

# Parse file with pyx text.
sub parse_file {
	my ($self, $file, $out) = @_;

	$self->{'pyx_parser'}->parse_file($file, $out);

	return;
}

# Parse from handler.
sub parse_handler {
	my ($self, $input_file_handler, $out) = @_;

	$self->{'pyx_parser'}->parse_handler($input_file_handler, $out);

	return;
}

# Process data.
sub _data {
	my ($pyx_parser_obj, $data) = @_;

	my $tmp = PYX::Utils::encode($data);
	if ($tmp =~ /^[\s\n]*$/) {
		return;
	}

	# TODO Preserve?

	# White space on begin of data.
	$tmp =~ s/^[\s\n]*//s;

	# White space on end of data.
	$tmp =~ s/[\s\n]*$//s;

	# White space on middle of data.
	$tmp =~ s/[\s\n]+/\ /sg;

	$data = PYX::Utils::decode($tmp);
	my $out = $pyx_parser_obj->{'output_handler'};
	my $encoded_output = Encode::encode(
		$pyx_parser_obj->{'non_parser_options'}->{'output_encoding'},
		char($data),
	);
	print {$out} $encoded_output, "\n";

	return;
}

# Process comment.
sub _comment {
	my ($pyx_parser_obj, $comment) = @_;

	my $tmp = PYX::Utils::encode($comment);
	if ($tmp =~ /^[\s\n]*$/) {
		return;
	}
	$tmp =~ s/^[\s\n]*//s;
	$tmp =~ s/[\s\n]*$//s;
	$comment = PYX::Utils::decode($tmp);
	my $out = $pyx_parser_obj->{'output_handler'};
	my $encoded_output = Encode::encode(
		$pyx_parser_obj->{'non_parser_options'}->{'output_encoding'},
		comment($comment),
	);
	print {$out} $encoded_output, "\n";

	return;
}

1;

__END__