File Coverage

blib/lib/POE/Component/RSS.pm

Criterion	Covered	Total	%
statement	7	9	77.7
branch			n/a
condition			n/a
subroutine	3	3	100.0
pod			n/a
total	10	12	83.3

package POE::Component::RSS;

=head1 NAME

POE::Component::RSS - Event based RSS parsing

=head1 SYNOPSIS

  use POE qw(Component::RSS);

  POE::Component::RSS->spawn();

  $kernel->post(
    'rss',
    'parse' => {
      Item => 'item_state',
    },
    $rss_string
  );

=head1 DESCRIPTION

POE::Component::RSS is an event based RSS parsing module. It wraps
XML::RSS and provides a POE based framework for accessing the information
provided.

=head1 INTERFACE

=cut

use warnings;
use strict;

use POE;
use Carp qw(croak);

use XML::RSS;
use Params::Validate qw(validate_with SCALAR);

our $VERSION = '3.01';

=head2 spawn

RSS parser components are not normal objects, but are instead 'spawned'
as separate sessions. This is done with PoCo::RSS's 'spawn' method, which
takes one named parameter:

=over 4

=item C<< Alias => $alias_name >>

'Alias' sets the name by which the session is known. If no alias
is given, the component defaults to 'rss'. It's possible to spawn
several RSS components with different names.

=back

=cut

sub spawn { #{{{
	my $class = shift;

	my %params = validate_with(
		params => \@_,
		spec => {
			Alias => {
				type => SCALAR,
				default => 'rss',
				optional => 1,
			},
		},
	);

	my $alias = delete $params{'Alias'};

	POE::Session->create(
		inline_states => {
			_start => \&rss_start,
			_stop  => sub {},
			parse  => \&got_parse,
		},
		args => [ $alias ],
	);

	return;
} #}}}


=begin devel

=head2 got_parse

Accepts parse requests, runs the documents through XML::Parser and generates
events. Unfortunately, this call is entirely blocking and, if given a sizeable
document, could take a while to return.

=cut

sub got_parse { #{{{
	my ($return_states, $rss_string, $rss_identity_tag) = @_[ARG0, ARG1, ARG2];

	my @rss_tag;

	if (defined($rss_identity_tag)) {
		@rss_tag = ($rss_identity_tag);
	} else {
		@rss_tag = ();
	}

	my $rss_parser = XML::RSS->new();

	$rss_parser->parse($rss_string);

	if (exists $return_states->{'Start'}) {
		$_[KERNEL]->post(
			$_[SENDER],
			$return_states->{'Start'},
			@rss_tag
		);
	}

	if (exists $return_states->{'Item'}) {
		foreach my $item (@{$rss_parser->{'items'}}) {
			# $item->{'title'}
			# $item->{'link'}
			$_[KERNEL]->post(
				$_[SENDER],
				$return_states->{'Item'},
				@rss_tag,
				$item
			);
		}
	}

	if (exists $return_states->{'Channel'}) {
		$_[KERNEL]->post(
			$_[SENDER],
			$return_states->{'Channel'},
			@rss_tag,
			$rss_parser->{'channel'}
		);
	}

	if (exists $return_states->{'Image'}) {
		$_[KERNEL]->post(
			$_[SENDER],
			$return_states->{'Image'},
			@rss_tag,
			$rss_parser->{'image'}
		);
	}

	if (exists $return_states->{'Textinput'}) {
		$_[KERNEL]->post(
			$_[SENDER],
			$return_states->{'Textinput'},
			@rss_tag,
			$rss_parser->{'textinput'}
		);
	}

	if (exists $return_states->{'Stop'}) {
		$_[KERNEL]->post(
			$_[SENDER],
			$return_states->{'Stop'},
			@rss_tag
		);
	}

	return;

} #}}}


=head2 rss_start

Just sets our alias

=cut

sub rss_start { #{{{
	$_[KERNEL]->alias_set($_[ARG0]);
} #}}}

1;
__END__