File Coverage

blib/lib/PDF/Make/Builder/Page.pm

Criterion	Covered	Total	%
statement	68	68	100.0
branch	14	16	87.5
condition	2	3	66.6
subroutine	15	15	100.0
pod	8	11	72.7
total	107	113	94.6

package PDF::Make::Builder::Page;
use strict;
use warnings;
use Object::Proto;

BEGIN {
    Object::Proto::define('PDF::Make::Builder::Page',
        'page_size:Str:default(A4)',
        'background:Str:default(#fff)',
        'columns:Int:default(1)',
        'column:Int:default(1)',
        'column_y:Num:default(0)',
        'is_rotated:Bool:default(0)',
        'header:Any',
        'footer:Any',
        'padding:Num:default(20)',
        'num:Int:required',
        'x:Num:default(0)',
        'y:Num:default(0)',
        'w:Num:required',
        'h:Num:required',
        'canvas:Any:required',
        'xs_page:Any:required',
        'imported:Bool:default(0)',
        'redactions:ArrayRef:default([])',
    );
    Object::Proto::import_accessors('PDF::Make::Builder::Page', 'page_');
}

my %PAGE_SIZES = (
    A4      => [595, 842],
    Letter  => [612, 792],
    Legal   => [612, 1008],
    A3      => [842, 1191],
    A5      => [420, 595],
    B5      => [499, 709],
    Tabloid => [792, 1224],
);

sub page_dimensions {
    my ($class_or_size) = @_;
    my $size = ref $class_or_size ? $class_or_size->page_size : $class_or_size;
    return @{$PAGE_SIZES{$size} // $PAGE_SIZES{A4}};
}

sub top_y {
    my ($self) = @_;
    my $ph = page_h $self;
    my $pad = page_padding $self;
    my $hdr = page_header $self;
    my $top = $ph - $pad;
    $top -= $hdr->h if $hdr;
    return $top;
}

sub bottom_y {
    my ($self) = @_;
    my $pad = page_padding $self;
    my $ftr = page_footer $self;
    my $bot = $pad;
    $bot += $ftr->h if $ftr;
    return $bot;
}

sub remaining_height {
    my ($self) = @_;
    return $self->cursor_y - $self->bottom_y;
}

sub width {
    my ($self) = @_;
    my $pw = page_w $self;
    my $pad = page_padding $self;
    my $cols = page_columns $self;
    my $usable = $pw - 2 * $pad;
    if ($cols > 1) {
        my $col_gap = 20;
        return ($usable - ($cols - 1) * $col_gap) / $cols;
    }
    return $usable;
}

sub content_x {
    my ($self) = @_;
    my $pad = page_padding $self;
    my $col = page_column $self;
    if ((page_columns $self) > 1) {
        my $col_gap = 20;
        my $col_w = $self->width;
        return $pad + ($col - 1) * ($col_w + $col_gap);
    }
    return $pad;
}

sub cursor_y {
    my ($self) = @_;
    my $cy = page_y $self;
    return $cy > 0 ? $cy : $self->top_y;
}

sub advance_y {
    my ($self, $amount) = @_;
    my $current = $self->cursor_y;
    page_y $self, $current - $amount;
}

sub has_next_column {
    my ($self) = @_;
    return (page_column $self) < (page_columns $self);
}

sub next_column {
    my ($self) = @_;
    my $col = page_column $self;
    my $cols = page_columns $self;
    return 0 if $col >= $cols;

    # Save cursor for the column we're leaving (for balanced columns)
    if ($col == 1) {
        page_column_y $self, $self->cursor_y;
    }

    page_column $self, $col + 1;
    # Reset cursor to top of content area for the new column
    page_y $self, $self->top_y;
    return 1;
}

sub reset_columns {
    my ($self) = @_;
    page_column $self, 1;
    page_column_y $self, 0;
    page_y $self, $self->top_y;
}

1;

__END__