File Coverage

blib/lib/PDF/Make/Builder/Page/Footer.pm

Criterion	Covered	Total	%
statement	37	39	94.8
branch	6	8	75.0
condition	1	2	50.0
subroutine	6	6	100.0
pod	1	1	100.0
total	51	56	91.0

package PDF::Make::Builder::Page::Footer;
use strict;
use warnings;
use Object::Proto;
use PDF::Make::Builder::Page::HeaderFooterContext;

BEGIN {
    Object::Proto::define('PDF::Make::Builder::Page::Footer',
        'h:Num:default(30)',
        'padding:Num:default(20)',
        'show_page_num:Str',
        'page_num_text:Str:default(Page {num})',
        'cb:CodeRef',
    );
    Object::Proto::import_accessors('PDF::Make::Builder::Page::Footer');
}

sub render {
    my ($self, $builder, $page, $page_num) = @_;
    my $canvas = $page->canvas;
    my $pw = $page->w;
    my $pad = padding $self;
    my $fh = $self->h;

    # Footer region: bottom of page
    my $footer_y = $pad + $fh;

    # Custom callback
    my $callback = cb $self;
    if ($callback) {
        my $ctx = PDF::Make::Builder::Page::HeaderFooterContext->new(
            builder => $builder,
            page    => $page,
            canvas  => $canvas,
            x0      => 0,
            y0      => $pad,
            w       => $pw,
            h       => $fh,
            padding => $pad,
            num     => $page_num,
            role    => 'footer',
        );
        $callback->($self, $builder,
            ctx    => $ctx,
            canvas => $canvas, y => $footer_y, w => $pw, h => $fh,
            page_num => $page_num);
    }

    # Page number
    my $show = show_page_num $self;
    if ($show) {
        my $text = page_num_text $self;
        $text =~ s/\{num\}/$page_num/g;
        my $font = $builder->font;
        my $res = $font->ensure_loaded($page->xs_page, 'normal');
        my $font_size = 8;
        my ($r, $g, $b) = $font->hex_to_rgb('#666');
        my $tw = $font->measure_text($text) * ($font_size / ($font->size || 9));
        my $tx;
        if ($show eq 'right') {
            $tx = $pw - $pad - $tw;
        } elsif ($show eq 'center') {
            $tx = ($pw - $tw) / 2;
        } else {
            $tx = $pad;
        }
        $canvas->BT
               ->rg($r, $g, $b)
               ->Tf($res, $font_size)
               ->Tm(1, 0, 0, 1, $tx, $pad + 4)
               ->Tj($text)
               ->ET;
    }
}

1;

__END__