File Coverage

blib/lib/PAGI/Utils.pm

Criterion	Covered	Total	%
statement	46	46	100.0
branch	27	28	96.4
condition	6	8	75.0
subroutine	10	10	100.0
pod	3	3	100.0
total	92	95	96.8

package PAGI::Utils;
$PAGI::Utils::VERSION = '0.002001';
use strict;
use warnings;
use Exporter 'import';
use Future::AsyncAwait;
use Carp qw(croak);
use Scalar::Util qw(blessed);
use PAGI::Lifespan;

our @EXPORT_OK = qw(handle_lifespan to_app is_response);
our %EXPORT_TAGS = (all => \@EXPORT_OK);

# True if $x is a PAGI response value: a blessed object that can respond($send).
# The single source of truth for the "did the handler return a response?" check
# (used by the endpoint and router dispatch paths).
sub is_response {
    my ($x) = @_;
    return blessed($x) && $x->can('respond') ? 1 : 0;
}

async sub handle_lifespan {
    my ($scope, $receive, $send, %opts) = @_;

    my $type = $scope->{type} // '';
    croak "handle_lifespan called with scope type '$type' (expected 'lifespan'). "
        . "Check scope type before calling: "
        . "return await handle_lifespan(...) if \$scope->{type} eq 'lifespan'"
        unless $type eq 'lifespan';

    my $manager = PAGI::Lifespan->for_scope($scope);
    $manager->register(%opts) if $opts{startup} || $opts{shutdown};

    return await $manager->handle($scope, $receive, $send);
}

sub to_app {
    my ($thing) = @_;

    croak "to_app() requires an app, component, or class name"
        unless defined $thing;

    return $thing if ref($thing) eq 'CODE';

    if (blessed($thing)) {
        return $thing->to_app if $thing->can('to_app');
        croak ref($thing) . " looks like middleware, not an app"
            . " - pass it to enable(), or wrap an app with ->wrap(\$app)"
            if $thing->can('wrap');
        croak "Cannot coerce " . ref($thing) . " object to a PAGI app (no to_app method)";
    }

    if (!ref($thing)) {
        croak "Cannot coerce '$thing' to a PAGI app"
            unless $thing =~ /\A\w+(?:::\w+)*\z/;
        unless ($thing->can('to_app')) {
            local $@;
            eval "require $thing; 1" or croak "Failed to load '$thing': $@";
        }
        return $thing->to_app if $thing->can('to_app');
        croak "'$thing' looks like middleware, not an app - pass it to enable()"
            if $thing->can('wrap');
        croak "'$thing' does not have a to_app() method";
    }

    croak "Cannot coerce " . ref($thing) . " reference to a PAGI app";
}

1;

__END__