File Coverage

lib/PAGI/App/Healthcheck.pm

Criterion	Covered	Total	%
statement	41	41	100.0
branch	14	14	100.0
condition	2	2	100.0
subroutine	7	7	100.0
pod	0	2	0.0
total	64	66	96.9

package PAGI::App::Healthcheck;

use strict;
use warnings;
use Future::AsyncAwait;
use JSON::MaybeXS ();

=head1 NAME

PAGI::App::Healthcheck - Health check endpoint app

=head1 SYNOPSIS

    use PAGI::App::Healthcheck;

    my $app = PAGI::App::Healthcheck->new(
        checks => {
            database => sub { check_db() },
        },
    )->to_app;

=cut

our $START_TIME = time();

sub new {
    my ($class, %args) = @_;

    return bless {
        checks  => $args{checks} // {},
        version => $args{version},
    }, $class;
}

sub to_app {
    my ($self) = @_;

    my $checks = $self->{checks};
    my $version = $self->{version};

    return async sub  {
        my ($scope, $receive, $send) = @_;
        my $all_ok = 1;
        my %results;

        for my $name (sort keys %$checks) {
            my $check = $checks->{$name};
            my $result = { status => 'ok' };

            eval { my $ok = $check->(); $result->{status} = 'error' unless $ok; };
            if ($@) {
                $result->{status} = 'error';
                $result->{message} = "$@";
                $result->{message} =~ s/\s+$//;
            }

            $results{$name} = $result;
            $all_ok = 0 if $result->{status} eq 'error';
        }

        my $response = {
            status    => $all_ok ? 'ok' : 'error',
            timestamp => time(),
            uptime    => time() - $START_TIME,
        };
        $response->{version} = $version if defined $version;
        $response->{checks} = \%results if %results;

        my $body = JSON::MaybeXS::encode_json($response);
        my $status = $all_ok ? 200 : 503;

        await $send->({
            type => 'http.response.start',
            status => $status,
            headers => [
                ['content-type', 'application/json'],
                ['content-length', length($body)],
                ['cache-control', 'no-cache'],
            ],
        });
        await $send->({ type => 'http.response.body', body => $body, more => 0 });
    };
}

1;

__END__