File Coverage

blib/lib/OpenSearch/Client/Error.pm

Criterion	Covered	Total	%
statement	43	58	74.1
branch	17	26	65.3
condition	6	13	46.1
subroutine	7	9	77.7
pod	0	4	0.0
total	73	110	66.3

# OpenSearch::Client is an unofficial client for OpenSearch.
# It is derived from Search::Elasticsearch version 7.714
# License details from that work are contained in the NOTICE
# file distributed with this work.
#-----------------------------------------------------------------------
# OpenSearch::Client
#-----------------------------------------------------------------------
# Copyright 2026 Mark Dootson
#
# Licensed under the Apache License, Version 2.0 (the "License");
# you may not use this file except in compliance with the License.
# You may obtain a copy of the License at
#
#     http://www.apache.org/licenses/LICENSE-2.0
#
# Unless required by applicable law or agreed to in writing, software
# distributed under the License is distributed on an "AS IS" BASIS,
# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
# See the License for the specific language governing permissions and
# limitations under the License.

package OpenSearch::Client::Error;
$OpenSearch::Client::Error::VERSION = '3.007002';
our $DEBUG = 0;

@OpenSearch::Client::Error::Internal::ISA     = __PACKAGE__;
@OpenSearch::Client::Error::Param::ISA        = __PACKAGE__;
@OpenSearch::Client::Error::NoNodes::ISA      = __PACKAGE__;
@OpenSearch::Client::Error::Unauthorized::ISA = __PACKAGE__;
@OpenSearch::Client::Error::Forbidden::ISA    = __PACKAGE__;
@OpenSearch::Client::Error::Illegal::ISA      = __PACKAGE__;
@OpenSearch::Client::Error::Request::ISA      = __PACKAGE__;
@OpenSearch::Client::Error::Timeout::ISA      = __PACKAGE__;
@OpenSearch::Client::Error::Cxn::ISA          = __PACKAGE__;
@OpenSearch::Client::Error::Serializer::ISA   = __PACKAGE__;

@OpenSearch::Client::Error::Conflict::ISA
    = ( 'OpenSearch::Client::Error::Request', __PACKAGE__ );

@OpenSearch::Client::Error::Missing::ISA
    = ( 'OpenSearch::Client::Error::Request', __PACKAGE__ );

@OpenSearch::Client::Error::RequestTimeout::ISA
    = ( 'OpenSearch::Client::Error::Request', __PACKAGE__ );

@OpenSearch::Client::Error::ContentLength::ISA
    = ( __PACKAGE__, 'OpenSearch::Client::Error::Request' );

@OpenSearch::Client::Error::SSL::ISA
    = ( __PACKAGE__, 'OpenSearch::Client::Error::Cxn' );

@OpenSearch::Client::Error::BadGateway::ISA
    = ( 'OpenSearch::Client::Error::Cxn', __PACKAGE__ );

@OpenSearch::Client::Error::Unavailable::ISA
    = ( 'OpenSearch::Client::Error::Cxn', __PACKAGE__ );

@OpenSearch::Client::Error::GatewayTimeout::ISA
    = ( 'OpenSearch::Client::Error::Cxn', __PACKAGE__ );

use overload (
    '""'  => '_stringify',
    'cmp' => '_compare',
);

use Data::Dumper();

#===================================
sub new {
#===================================
    my ( $class, $type, $msg, $vars, $caller ) = @_;
    return $type if ref $type;
    $caller ||= 0;

    my $error_class = 'OpenSearch::Client::Error::' . $type;
    $msg = 'Unknown error' unless defined $msg;

    local $DEBUG = 2 if $type eq 'Internal';

    my $stack = $class->_stack;

    my $self = bless {
        type  => $type,
        text  => $msg,
        vars  => $vars,
        stack => $stack,
    }, $error_class;

    return $self;
}

#===================================
sub is {
#===================================
    my $self = shift;
    for (@_) {
        return 1 if $self->isa("OpenSearch::Client::Error::$_");
    }
    return 0;
}

#===================================
sub _stringify {
#===================================
    my $self = shift;
    local $Data::Dumper::Terse  = 1;
    local $Data::Dumper::Indent = !!$DEBUG;

    unless ( $self->{msg} ) {
        my $stack  = $self->{stack};
        my $caller = $stack->[0];
        $self->{msg} = sprintf( "[%s] ** %s, called from sub %s at %s line %d.",
            $self->{type}, $self->{text}, @{$caller}[ 3, 1, 2 ] );

        if ( $self->{vars} ) {
            $self->{msg} .= sprintf( " With vars: %s\n",
                Data::Dumper::Dumper $self->{vars} );
        }

        if ( @$stack > 1 ) {
            $self->{msg}
                .= sprintf( "Stacktrace:\n%s\n", $self->stacktrace($stack) );
        }
    }
    return $self->{msg};

}

#===================================
sub _compare {
#===================================
    my ( $self, $other, $swap ) = @_;
    $self .= '';
    ( $self, $other ) = ( $other, $self ) if $swap;
    return $self cmp $other;
}

#===================================
sub _stack {
#===================================
    my $self = shift;
    my $caller = shift() || 2;

    my @stack;
    while ( my @caller = caller( ++$caller ) ) {
        next if $caller[0] eq 'Try::Tiny';

        if ( $caller[3] =~ /^(.+)::__ANON__\[(.+):(\d+)\]$/ ) {
            @caller = ( $1, $2, $3, '(ANON)' );
        }
        elsif ( $caller[1] =~ /^\(eval \d+\)/ ) {
            $caller[3] = "modified(" . $caller[3] . ")";
        }

        next
            if $caller[0] =~ /^OpenSearch::Client/
            and ( $DEBUG < 2 or $caller[3] eq 'Try::Tiny::try' );
        push @stack, [ @caller[ 0, 1, 2, 3 ] ];
        last unless $DEBUG > 1;
    }
    return \@stack;
}

#===================================
sub stacktrace {
#===================================
    my $self = shift;
    my $stack = shift || $self->_stack();

    my $o = sprintf "%s\n%-4s %-50s %-5s %s\n%s\n",
        '-' x 80, '#', 'Package', 'Line', 'Sub-routine', '-' x 80;

    my $i = 1;
    for (@$stack) {
        $o .= sprintf "%-4d %-50s %4d  %s\n", $i++, @{$_}[ 0, 2, 3 ];
    }

    return $o .= ( '-' x 80 ) . "\n";
}

#===================================
sub TO_JSON {
#===================================
    my $self = shift;
    return $self->_stringify;
}
1;

__END__