File Coverage

script/ot

Criterion	Covered	Total	%
statement	45	57	78.9
branch	10	20	50.0
condition	1	3	33.3
subroutine	7	7	100.0
pod			n/a
total	63	87	72.4

#!perl

use strict;
use warnings;

use Getopt::Long qw( GetOptions );
use Open::This   qw(
    editor_args_from_parsed_text
    maybe_get_url_from_parsed_text
    parse_text
);
use Path::Tiny qw( path );
use Pod::Usage qw( pod2usage );

pod2usage("Error: missing argument\n") unless @ARGV;

my $browse;
my $editor;
my $json;
my $print;

GetOptions(
    'browse|b'   => \$browse,
    'editor|e=s' => \$editor,
    'json|j'     => \$json,
    'print|p'    => \$print,
);

my $parsed = parse_text(@ARGV);
if ( !$parsed ) {
    exit_with_error( 'Could not locate file', join ' ', @ARGV );
}

if ($browse) {
    my $url = maybe_get_url_from_parsed_text($parsed);
    if ( !exists $parsed->{remote_file_url} ) {
        exit_with_error( 'Could not find remote repository', $parsed );
    }

    # A relative path should be inside our repository
    if ( path( $parsed->{remote_file_url} )->is_relative ) {
        require Browser::Open;
        Browser::Open::open_browser( $parsed->{remote_file_url} );
        exit(0);
    }
    return undef;
}

local $ENV{EDITOR} = $editor || $ENV{EDITOR};

unless ( $ENV{EDITOR} ) {
    exit_with_error(
        'Please set your $EDITOR env var or use the --editor arg');
}

my @editor_args = editor_args_from_parsed_text($parsed);

if ($json) {
    require Cpanel::JSON::XS;    ## no perlimports
    my $json = Cpanel::JSON::XS->new->canonical->encode(
        {
            editor      => $ENV{EDITOR},
            editor_args => \@editor_args,
            success     => Cpanel::JSON::XS::true(),
        }
    );
    print STDOUT $json, "\n";
    exit(0);
}
if ($print) {
    print STDOUT join( ' ', @editor_args ), "\n";
    exit(0);
}

sub exit_with_error {
    my $error   = shift;
    my $details = shift;
    unless ($json) {
        print STDERR $error, "\n";
        exit(1);
    }
    require Cpanel::JSON::XS;    ## no perlimports
    my $json = Cpanel::JSON::XS->new->canonical->encode(
        {
            ( $details ? ( details => $details ) : () ),
            error   => $error,
            success => Cpanel::JSON::XS::false(),
        }
    );
    print STDOUT $json, "\n";
    exit(1);
}

exec $ENV{EDITOR}, @editor_args;

# ABSTRACT: parse text and (hopefully) open an editor with the correct arguments
# PODNAME: ot

__END__