File Coverage

blib/lib/NetSDS/Logger.pm

Criterion	Covered	Total	%
statement	12	32	37.5
branch	0	8	0.0
condition	0	3	0.0
subroutine	4	7	57.1
pod	2	2	100.0
total	18	52	34.6

#===============================================================================
#
#         FILE:  Logger.pm
#
#  DESCRIPTION:  Syslog wrapper for Net SDS
#
#       AUTHOR:  Michael Bochkaryov (Rattler),
#      COMPANY:  Net.Style
#      CREATED:  25.04.2008 17:32:37 EEST
#===============================================================================

=head1 NAME

NetSDS::Logger - syslog wrapper for applications and classes

=head1 SYNOPSIS

	use NetSDS::Logger;

	my $logger = NetSDS::Logger->new(
		name => 'NetSDS-SuperDaemon',
	);
	$logger->log("info", "Syslog message here");

=head1 DESCRIPTION

This module contains implementation of logging functionality for NetSDS components.

By default, messages are logged with C facility and C options.

B: C module is for internal use mostly from application
frameworks like C, C, etc.

=cut

package NetSDS::Logger;

use 5.8.0;
use warnings;

use Unix::Syslog qw(:macros :subs);

use version; our $VERSION = '1.301';

#===============================================================================

=head1 CLASS API

=over

=item B - constructor

Constructor B creates new logger object and opens socket with default
NetSDS logging parameters.

Arguments allowed (as hash):

B - application name for identification

	Use only ASCII characters in "name" to avoid possible errors.
	Default value is "NetSDS".

B - logging facility

	Available facility values:

		* local0..local7
		* user
		* daemon

	If not set 'local0' is used as default value

=cut

#-----------------------------------------------------------------------
sub new {

	my ( $class, %params ) = @_;

	my $self = {};

	# Set application identification name
	my $name = 'NetSDS';
	if ( $params{name} ) {
		$name = $params{name};
	}

	# Set logging facility
	my %facility_map = (
		'local0' => LOG_LOCAL0,
		'local1' => LOG_LOCAL1,
		'local2' => LOG_LOCAL2,
		'local3' => LOG_LOCAL3,
		'local4' => LOG_LOCAL4,
		'local5' => LOG_LOCAL5,
		'local6' => LOG_LOCAL6,
		'local7' => LOG_LOCAL7,
		'user'   => LOG_USER,
		'daemon' => LOG_DAEMON,
	);

	my $facility = LOG_LOCAL0;    # default is local0
	if ( $params{facility} ) {
		$facility = $facility_map{ $params{facility} } || LOG_LOCAL0;
	}

	openlog( $name, LOG_PID | LOG_CONS | LOG_NDELAY, $facility );

	return bless $self, $class;

} ## end sub new

#***********************************************************************

=item B - write record to log

Wrapper to C method of L module.

Level is passed as string and may be one of the following:

	alert	- LOG_ALERT
	crit	- LOG_CRIT
	debug	- LOG_DEBUG
	emerg	- LOG_EMERG
	error	- LOG_ERR
	info	- LOG_INFO
	notice	- LOG_NOTICE
	warning	- LOG_WARNING

=cut

#-----------------------------------------------------------------------
sub log {

	my ( $self, $level, $message ) = @_;

	# Level aliases
	my %LEVFIX = (
		alert     => LOG_ALERT,
		crit      => LOG_CRIT,
		critical  => LOG_CRIT,
		deb       => LOG_DEBUG,
		debug     => LOG_DEBUG,
		emerg     => LOG_EMERG,
		emergency => LOG_EMERG,
		panic     => LOG_EMERG,
		err       => LOG_ERR,
		error     => LOG_ERR,
		inf       => LOG_INFO,
		info      => LOG_INFO,
		inform    => LOG_INFO,
		note      => LOG_NOTICE,
		notice    => LOG_NOTICE,
		warning   => LOG_WARNING,
		warn      => LOG_WARNING,
	);

	my $LEV = $LEVFIX{$level};

	if ( !$LEV ) {
		$LEV = LOG_INFO;
	}

	if ( !$message ) {
		$message = "";
	}

	syslog( $LEV, "[$level] $message" );

} ## end sub log

#***********************************************************************

=item B - class destructor

Destructor (DESTROY method) calls C function. That's all.

=cut

#-----------------------------------------------------------------------
sub DESTROY {

	closelog();

}

1;

__END__