File Coverage

blib/lib/Net/SecurityCenter/API/Scanner.pm

Criterion	Covered	Total	%
statement	46	56	82.1
branch	7	18	38.8
condition			n/a
subroutine	9	10	90.0
pod	4	5	80.0
total	66	89	74.1

package Net::SecurityCenter::API::Scanner;

use warnings;
use strict;

use Carp;

use parent 'Net::SecurityCenter::Base';

use Net::SecurityCenter::Utils qw(:all);

our $VERSION = '0.300';

my $common_template = {

    id => {
        required => 1,
        allow    => qr/^\d+$/,
        messages => {
            required => 'Scanner ID is required',
            allow    => 'Invalid Scanner ID',
        },
    },

    fields => {
        filter => \&sc_filter_array_to_string,
    }

};

#-------------------------------------------------------------------------------
# METHODS
#-------------------------------------------------------------------------------

sub list {

    my ( $self, %args ) = @_;

    my $tmpl = {
        fields => $common_template->{'fields'},
        raw    => {}
    };

    my $params   = sc_check_params( $tmpl, \%args );
    my $raw      = delete( $params->{'raw'} );
    my $scanners = $self->client->get( '/scanner', $params );

    return if ( !$scanners );

    if ($raw) {
        return wantarray ? @{$scanners} : $scanners;
    }

    return wantarray ? @{ sc_normalize_array($scanners) } : sc_normalize_array($scanners);

}

#-------------------------------------------------------------------------------

sub get {

    my ( $self, %args ) = @_;

    my $tmpl = {
        fields => $common_template->{'fields'},
        id     => $common_template->{'id'},
        raw    => {},
    };

    my $params     = sc_check_params( $tmpl, \%args );
    my $scanner_id = delete( $params->{'id'} );
    my $raw        = delete( $params->{'raw'} );
    my $scanner    = $self->client->get( "/scanner/$scanner_id", $params );

    return          if ( !$scanner );
    return $scanner if ($raw);
    return sc_normalize_hash($scanner);

}

#-------------------------------------------------------------------------------

sub status {

    my ( $self, %args ) = @_;

    my $tmpl = { id => $common_template->{'id'}, };

    my $params     = sc_check_params( $tmpl, \%args );
    my $scanner_id = delete( $params->{'id'} );

    my $scanner = $self->get( id => $scanner_id, fields => [ 'id', 'status' ] );

    return if ( !$scanner );
    return sc_decode_scanner_status( $scanner->{'status'} );

}

#-------------------------------------------------------------------------------

sub health {

    my ( $self, %args ) = @_;

    my $tmpl = { id => $common_template->{'id'}, count => {} };

    my $params     = sc_check_params( $tmpl, \%args );
    my $scanner_id = delete( $params->{'id'} );

    my $scanner = $self->client->get("/scanner/$scanner_id/health");

    return if ( !$scanner );
    return $scanner;

}

#-------------------------------------------------------------------------------

sub bug_report {

    my ( $self, %args ) = @_;

    my $tmpl = { id => $common_template->{'id'}, scrub_mode => {}, full_mode => {} };

    my $params     = sc_check_params( $tmpl, \%args );
    my $scanner_id = delete( $params->{'id'} );

    my $scanner = $self->client->get( "/scanner/$scanner_id/bug_report", $params );

    return if ( !$scanner );
    return $scanner;

}

#-------------------------------------------------------------------------------

1;

__END__