File Coverage

blib/lib/Net/Google/CivicInformation/Representatives.pm

Criterion	Covered	Total	%
statement	31	57	54.3
branch	0	8	0.0
condition			n/a
subroutine	12	15	80.0
pod	1	1	100.0
total	44	81	54.3

package Net::Google::CivicInformation::Representatives;

our $VERSION = '1.9901';

use strict;
use warnings;
use v5.10;

use Carp 'croak';
use Function::Parameters;
use JSON::MaybeXS;
use Try::Tiny;

use Types::Common::String 'NonEmptyStr';
use Moo;
use namespace::clean;

extends 'Net::Google::CivicInformation';

BEGIN {
    warn 'Net::Google::CivicInformation::Representatives is deprecated (Google terminated the API) and should no longer be used';
}

##
sub _build__api_url {
    return 'representatives';
}

##
method representatives_for_address (NonEmptyStr $address) {
    my $uri = URI->new( $self->_api_url );
    $uri->query_form(
        address => $address,
        key => $self->api_key,
    );

    my $call = $self->_client->get( $uri );

    my $response;
    try {
        if ( ! $call->{success} ) {
            my $resp = decode_json( $call->{content} );
            $response = $resp;
        }
        else {
            my $data = decode_json( $call->{content} );

            my @result;

            my @officials = @{ $data->{officials} };

            for my $job ( @{ $data->{offices} } ) {

                for my $person ( @officials[ @{ $job->{officialIndices} } ] ) {
                    push( @result, {
                        title         => $job->{name},
                        name          => $person->{name},
                        party         => $person->{party},
                        addresses     => $person->{address},
                        phone_numbers => $person->{phones},
                        emails        => $person->{emails},
                        websites      => $person->{urls},
                        social_media  => $person->{channels},
                    });

                }
            }

            $response = { officials => \@result };
        }
    }
    catch {
        $response = {
            error => {
                message => 'Caught fatal error trying to call Google API',
            },
        };
    };

    return $response;
}

1; # return true

__END__