File Coverage

blib/lib/Net/Frame/Layer/MPLS.pm

Criterion	Covered	Total	%
statement	54	62	87.1
branch	5	18	27.7
condition			n/a
subroutine	14	15	93.3
pod	6	6	100.0
total	79	101	78.2

#
# $Id: MPLS.pm 49 2009-05-31 13:15:34Z VinsWorldcom $
#
package Net::Frame::Layer::MPLS;
use strict; use warnings;

our $VERSION = '1.00';

use Net::Frame::Layer qw(:consts :subs);
use Exporter;
our @ISA = qw(Net::Frame::Layer Exporter);

our %EXPORT_TAGS = (
   consts => [qw(
      NF_MPLS_S_NO
      NF_MPLS_S_YES
   )],
);
our @EXPORT_OK = (
   @{$EXPORT_TAGS{consts}},
);

use constant NF_MPLS_S_NO  => 0;
use constant NF_MPLS_S_YES => 1;

our @AS = qw(
   label
   tc
   s
   ttl
);
__PACKAGE__->cgBuildIndices;
__PACKAGE__->cgBuildAccessorsScalar(\@AS);

#no strict 'vars';
use Bit::Vector;
use Net::Frame::Layer::MPLS::PWACH qw(:consts);
use Net::Frame::Layer::MPLS::PWMCW qw(:consts);

sub new {
   shift->SUPER::new(
      label => 0,
      tc    => 0,
      s     => NF_MPLS_S_YES,
      ttl   => 255,
      @_,
   );
}

sub getLength { 4 }

sub pack {
   my $self = shift;

   my $label  = Bit::Vector->new_Dec(20, $self->label);
   my $tc     = Bit::Vector->new_Dec(3, $self->tc);
   my $s      = Bit::Vector->new_Dec(1, $self->s);
   my $ttl    = Bit::Vector->new_Dec(8, $self->ttl);
   my $bvlist = $label->Concat_List($tc, $s, $ttl);

   my $raw = $self->SUPER::pack('N',
      $bvlist->to_Dec
   ) or return;

   return $self->raw($raw);
}

sub unpack {
   my $self = shift;

   my ($bv, $payload) =
      $self->SUPER::unpack('N a*', $self->raw)
         or return;

   my $bvlist = Bit::Vector->new_Dec(32, $bv);
   $self->label($bvlist->Chunk_Read(20,12));
   $self->tc   ($bvlist->Chunk_Read(3,9));
   $self->s    ($bvlist->Chunk_Read(1,8));
   $self->ttl  ($bvlist->Chunk_Read(8,0));

   $self->payload($payload);

   return $self;
}

sub encapsulate {
   my $self = shift;

   return $self->nextLayer if $self->nextLayer;

   if (!$self->s) {
      return 'MPLS';
   }
   if ($self->payload) {
      my $payload = CORE::unpack('H', $self->payload);
      if ($payload == NF_MPLS_PWNIBBLE_MCW) {
         return 'MPLS::PWMCW';
      } elsif ($payload == NF_MPLS_PWNIBBLE_ACH) {
         return 'MPLS::PWACH';
      } elsif ($payload == 4) {
         return 'IPv4';
      } elsif ($payload == 6) {
         return 'IPv6';
      }
   }

   NF_LAYER_NONE;
}

sub print {
   my $self = shift;

   my $l = $self->layer;
   my $buf = sprintf
      "$l: label:%d  tc:%d  s:%d  ttl:%d",
         $self->label, $self->tc, $self->s, $self->ttl;

   return $buf;
}

1;

__END__