File Coverage

blib/lib/Net/Frame/Layer/CDP/Address.pm

Criterion	Covered	Total	%
statement	52	71	73.2
branch	8	32	25.0
condition			n/a
subroutine	13	16	81.2
pod	8	8	100.0
total	81	127	63.7

#
# $Id: Address.pm 1640 2009-11-09 17:58:27Z VinsWorldcom $
#
package Net::Frame::Layer::CDP::Address;
use strict; use warnings;

use Net::Frame::Layer qw(:consts :subs);
use Exporter;
our @ISA = qw(Net::Frame::Layer Exporter);

our %EXPORT_TAGS = (
   consts => [qw(
      NF_CDP_ADDRESS_PROTOCOL_TYPE_NLPID
      NF_CDP_ADDRESS_PROTOCOL_TYPE_8022
      NF_CDP_ADDRESS_PROTOCOL_IP
      NF_CDP_ADDRESS_PROTOCOL_IPv6
   )],
);
our @EXPORT_OK = (
   @{$EXPORT_TAGS{consts}},
);

use constant NF_CDP_ADDRESS_PROTOCOL_TYPE_NLPID => 1;
use constant NF_CDP_ADDRESS_PROTOCOL_TYPE_8022  => 2;
use constant NF_CDP_ADDRESS_PROTOCOL_IP   => CORE::pack 'H*', 'cc';
use constant NF_CDP_ADDRESS_PROTOCOL_IPv6 => CORE::pack 'H*', 'aaaa0300000086dd';

our @AS = qw(
   protocolType
   protocolLength
   protocol
   addressLength
   address
);
__PACKAGE__->cgBuildIndices;
__PACKAGE__->cgBuildAccessorsScalar(\@AS);

#no strict 'vars';

sub new {
   shift->SUPER::new(
      protocolType   => NF_CDP_ADDRESS_PROTOCOL_TYPE_NLPID,
      protocolLength => 1,
      protocol       => NF_CDP_ADDRESS_PROTOCOL_IP,
      addressLength  => 4,
      address        => '127.0.0.1',
      @_,
   );
}

sub ipv4Address {
   return new(@_)
}

sub ipv6Address {
   shift->SUPER::new(
      protocolType   => NF_CDP_ADDRESS_PROTOCOL_TYPE_8022,
      protocolLength => 8,
      protocol       => NF_CDP_ADDRESS_PROTOCOL_IPv6,
      addressLength  => 16,
      address        => '::1',
      @_,
   );
}

sub getLength {
   my $self = shift;

   my $length = 4;
   $length += length($self->protocol);
   $length += $self->addressLength;

   return $length
}

sub pack {
   my $self = shift;

   my $raw = $self->SUPER::pack('CC',
      $self->protocolType,
      $self->protocolLength
   ) or return;

   my $protocolLength = $self->protocolLength;
   $raw .= $self->SUPER::pack("a$protocolLength n",
      $self->protocol,
      $self->addressLength
   ) or return;

   my $addressLength = $self->addressLength;
   if ($self->protocol eq NF_CDP_ADDRESS_PROTOCOL_IP) {
      $raw .= $self->SUPER::pack('a4',
         inetAton($self->address)
      ) or return;
   } elsif ($self->protocol eq NF_CDP_ADDRESS_PROTOCOL_IPv6) {
      $raw .= $self->SUPER::pack('a16',
         inet6Aton($self->address)
      ) or return;
   } else {
      $raw .= $self->SUPER::pack("a$addressLength",
         $self->address
      ) or return;
   }

   return $self->raw($raw);
}

sub unpack {
   my $self = shift;

   my ($protocolType, $protocolLength, $tail) =
      $self->SUPER::unpack('CC a*', $self->raw)
         or return;

   $self->protocolType($protocolType);
   $self->protocolLength($protocolLength);

   my ($protocol, $addressLength);
   ($protocol, $addressLength, $tail) =
      $self->SUPER::unpack("a$protocolLength n a*", $tail)
         or return;

   $self->protocol($protocol);
   $self->addressLength($addressLength);

   my ($address, $payload);
   if ($self->protocol eq NF_CDP_ADDRESS_PROTOCOL_IP) {
      ($address, $payload) =
         $self->SUPER::unpack('a4 a*', $tail)
            or return;
      $self->address(inetNtoa($address));
   } elsif ($self->protocol eq NF_CDP_ADDRESS_PROTOCOL_IPv6) {
      ($address, $payload) =
         $self->SUPER::unpack('a16 a*', $tail)
            or return;
      $self->address(inet6Ntoa($address));
   } else {
      ($address, $payload) =
         $self->SUPER::unpack("a$addressLength a*", $tail)
            or return;
      $self->address($address);
   }

   $self->payload($payload);

   return $self;
}

sub computeLengths {
   my $self = shift;

   $self->protocolLength(length($self->protocol));

   if ($self->protocol eq NF_CDP_ADDRESS_PROTOCOL_IP) {
      $self->addressLength(4)
   } elsif ($self->protocol eq NF_CDP_ADDRESS_PROTOCOL_IPv6) {
      $self->addressLength(16)
   }else {
      return;
   }

   return 1;
}

sub print {
   my $self = shift;

   my $l = $self->layer;
   my $buf = sprintf
      "$l: protocolType:%d  protocolLength:%d  protocol:0x%s\n".
      "$l: addressLength:%d  address:%s",
         $self->protocolType, $self->protocolLength, (CORE::unpack 'H*', $self->protocol),
         $self->addressLength, $self->address;

   return $buf;
}

1;

__END__