File Coverage

blib/lib/Net/DNS/RR/ZONEMD.pm

Criterion	Covered	Total	%
statement	58	58	100.0
branch	4	4	100.0
path			n/a
condition	10	10	100.0
subroutine	15	15	100.0
pod	5	5	100.0
total	92	92	100.0

package Net::DNS::RR::ZONEMD;

use strict;
use warnings;
our $VERSION = (qw$Id: ZONEMD.pm 2003 2025-01-21 12:06:06Z willem $)[2];

use base qw(Net::DNS::RR);


=head1 NAME

Net::DNS::RR::ZONEMD - DNS ZONEMD resource record

=cut

use integer;

use Carp;


sub _decode_rdata {			## decode rdata from wire-format octet string
	my ( $self, $data, $offset ) = @_;

	my $rdata = substr $$data, $offset, $self->{rdlength};
	@{$self}{qw(serial scheme algorithm digestbin)} = unpack 'NC2a*', $rdata;
	return;
}


sub _encode_rdata {			## encode rdata as wire-format octet string
	my $self = shift;

	return pack 'NC2a*', @{$self}{qw(serial scheme algorithm digestbin)};
}


sub _format_rdata {			## format rdata portion of RR string.
	my $self = shift;

	my @digest = split /(\S{64})/, $self->digest || qq("");
	my @rdata  = ( @{$self}{qw(serial scheme algorithm)}, @digest );
	return @rdata;
}


sub _parse_rdata {			## populate RR from rdata in argument list
	my ( $self, @argument ) = @_;

	for (qw(serial scheme algorithm)) { $self->$_( shift @argument ) }
	$self->digest(@argument);
	return;
}


sub _defaults {				## specify RR attribute default values
	my $self = shift;

	$self->_parse_rdata( 0, 1, 1, '' );
	return;
}


sub serial {
	my ( $self, @value ) = @_;
	for (@value) { $self->{serial} = 0 + $_ }
	return $self->{serial} || 0;
}


sub scheme {
	my ( $self, @value ) = @_;
	for (@value) { $self->{scheme} = 0 + $_ }
	return $self->{scheme} || 0;
}


sub algorithm {
	my ( $self, @value ) = @_;
	for (@value) { $self->{algorithm} = 0 + $_ }
	return $self->{algorithm} || 0;
}


sub digest {
	my ( $self, @value ) = @_;
	return unpack "H*", $self->digestbin() unless scalar @value;
	my @hex = map { /^"*([\dA-Fa-f]*)"*$/ || croak("corrupt hex"); $1 } @value;
	return $self->digestbin( pack "H*", join "", @hex );
}


sub digestbin {
	my ( $self, @value ) = @_;
	for (@value) { $self->{digestbin} = $_ }
	return $self->{digestbin} || "";
}


1;
__END__