File Coverage

blib/lib/Net/DNS/RR/URI.pm

Criterion	Covered	Total	%
statement	46	46	100.0
branch	2	2	100.0
path			n/a
condition	4	4	100.0
subroutine	12	12	100.0
pod	3	3	100.0
total	67	67	100.0

package Net::DNS::RR::URI;

use strict;
use warnings;
our $VERSION = (qw$Id: URI.pm 2003 2025-01-21 12:06:06Z willem $)[2];

use base qw(Net::DNS::RR);


=head1 NAME

Net::DNS::RR::URI - DNS URI resource record

=cut

use integer;

use Net::DNS::Text;


sub _decode_rdata {			## decode rdata from wire-format octet string
	my ( $self, $data, $offset ) = @_;

	my $limit = $offset + $self->{rdlength};
	@{$self}{qw(priority weight)} = unpack( "\@$offset n2", $$data );
	$offset += 4;
	$self->{target} = Net::DNS::Text->decode( $data, $offset, $limit - $offset );
	return;
}


sub _encode_rdata {			## encode rdata as wire-format octet string
	my $self = shift;

	my $target = $self->{target};
	return pack 'n2 a*', @{$self}{qw(priority weight)}, $target->raw;
}


sub _format_rdata {			## format rdata portion of RR string.
	my $self = shift;

	my $target = $self->{target};
	my @rdata  = ( $self->priority, $self->weight, $target->string );
	return @rdata;
}


sub _parse_rdata {			## populate RR from rdata in argument list
	my ( $self, @argument ) = @_;

	for (qw(priority weight target)) { $self->$_( shift @argument ) }
	return;
}


sub priority {
	my ( $self, @value ) = @_;
	for (@value) { $self->{priority} = 0 + $_ }
	return $self->{priority} || 0;
}


sub weight {
	my ( $self, @value ) = @_;
	for (@value) { $self->{weight} = 0 + $_ }
	return $self->{weight} || 0;
}


sub target {
	my ( $self, @value ) = @_;
	for (@value) { $self->{target} = Net::DNS::Text->new($_) }
	return $self->{target} ? $self->{target}->value : undef;
}


# order RRs by numerically increasing priority, decreasing weight
my $function = sub {
	my ( $a, $b ) = ( $Net::DNS::a, $Net::DNS::b );
	return $a->{priority} <=> $b->{priority}
			|| $b->{weight} <=> $a->{weight};
};

__PACKAGE__->set_rrsort_func( 'priority', $function );

__PACKAGE__->set_rrsort_func( 'default_sort', $function );


1;
__END__