File Coverage

blib/lib/Net/DNS/RR/TXT.pm

Criterion	Covered	Total	%
statement	48	48	100.0
branch	6	6	100.0
path			n/a
condition	2	2	100.0
subroutine	12	12	100.0
pod	1	2	100.0
total	69	70	100.0

package Net::DNS::RR::TXT;

use strict;
use warnings;
our $VERSION = (qw$Id: TXT.pm 2003 2025-01-21 12:06:06Z willem $)[2];

use base qw(Net::DNS::RR);

=encoding utf8


=head1 NAME

Net::DNS::RR::TXT - DNS TXT resource record

=cut

use integer;

use Carp;
use Net::DNS::Text;


sub _decode_rdata {			## decode rdata from wire-format octet string
	my ( $self, $data, $offset ) = @_;

	my $limit = $self->{rdlength};
	my $rdata = substr $$data, $offset, $limit;
	my $array = $self->{txtdata} = [];
	my $index = 0;
	while ( $index < $limit ) {
		( my $text, $index ) = Net::DNS::Text->decode( \$rdata, $index );
		push @$array, $text;
	}
	return;
}


sub _encode_rdata {			## encode rdata as wire-format octet string
	my $self = shift;

	my $txtdata = $self->{txtdata};
	return join '', map { $_->encode } @$txtdata;
}


sub _format_rdata {			## format rdata portion of RR string.
	my $self = shift;

	my $txtdata = $self->{txtdata};
	return ( map { $_->unicode } @$txtdata );
}


sub _parse_rdata {			## populate RR from rdata in argument list
	my ( $self, @argument ) = @_;

	$self->{txtdata} = [map { Net::DNS::Text->new($_) } @argument];
	return;
}


sub txtdata {
	my ( $self, @value ) = @_;

	$self->{txtdata} = [map { Net::DNS::Text->new($_) } @value] if scalar @value;

	my $txtdata = $self->{txtdata} || [];

	return ( map { $_->value } @$txtdata ) if wantarray;

	return defined(wantarray) ? join( ' ', map { $_->value } @$txtdata ) : '';
}


sub char_str_list { return my @txt = &txtdata }			# uncoverable pod


1;
__END__