File Coverage

blib/lib/Net/DNS/RR/SSHFP.pm

Criterion	Covered	Total	%
statement	57	57	100.0
branch	4	4	100.0
path			n/a
condition	6	6	100.0
subroutine	16	16	100.0
pod	6	6	100.0
total	89	89	100.0

package Net::DNS::RR::SSHFP;

use strict;
use warnings;
our $VERSION = (qw$Id: SSHFP.pm 2003 2025-01-21 12:06:06Z willem $)[2];

use base qw(Net::DNS::RR);


=head1 NAME

Net::DNS::RR::SSHFP - DNS SSHFP resource record

=cut

use integer;

use Carp;

use constant BABBLE => defined eval { require Digest::BubbleBabble };


sub _decode_rdata {			## decode rdata from wire-format octet string
	my ( $self, $data, $offset ) = @_;

	my $size = $self->{rdlength} - 2;
	@{$self}{qw(algorithm fptype fpbin)} = unpack "\@$offset C2 a$size", $$data;
	return;
}


sub _encode_rdata {			## encode rdata as wire-format octet string
	my $self = shift;

	return pack 'C2 a*', @{$self}{qw(algorithm fptype fpbin)};
}


sub _format_rdata {			## format rdata portion of RR string.
	my $self = shift;

	$self->_annotation( $self->babble ) if BABBLE;
	my @fprint = split /(\S{64})/, $self->fp;
	my @rdata  = ( $self->algorithm, $self->fptype, @fprint );
	return @rdata;
}


sub _parse_rdata {			## populate RR from rdata in argument list
	my ( $self, @argument ) = @_;

	for (qw(algorithm fptype)) { $self->$_( shift @argument ) }
	$self->fp(@argument);
	return;
}


sub algorithm {
	my ( $self, @value ) = @_;
	for (@value) { $self->{algorithm} = 0 + $_ }
	return $self->{algorithm} || 0;
}


sub fptype {
	my ( $self, @value ) = @_;
	for (@value) { $self->{fptype} = 0 + $_ }
	return $self->{fptype} || 0;
}


sub fp {
	my ( $self, @value ) = @_;
	return unpack "H*", $self->fpbin() unless scalar @value;
	my @hex = map { /^"*([\dA-Fa-f]*)"*$/ || croak("corrupt hex"); $1 } @value;
	return $self->fpbin( pack "H*", join "", @hex );
}


sub fpbin {
	my ( $self, @value ) = @_;
	for (@value) { $self->{fpbin} = $_ }
	return $self->{fpbin} || "";
}


sub babble {
	return BABBLE ? Digest::BubbleBabble::bubblebabble( Digest => shift->fpbin ) : '';
}


sub fingerprint { return &fp; }		## historical


1;
__END__