File Coverage

blib/lib/Net/DNS/RR/RT.pm

Criterion	Covered	Total	%
statement	35	35	100.0
branch	2	2	100.0
path			n/a
condition	2	2	100.0
subroutine	11	11	100.0
pod	2	2	100.0
total	52	52	100.0

package Net::DNS::RR::RT;

use strict;
use warnings;
our $VERSION = (qw$Id: RT.pm 2003 2025-01-21 12:06:06Z willem $)[2];

use base qw(Net::DNS::RR);


=head1 NAME

Net::DNS::RR::RT - DNS RT resource record

=cut

use integer;

use Net::DNS::DomainName;


sub _decode_rdata {			## decode rdata from wire-format octet string
	my ( $self, $data, $offset, @opaque ) = @_;

	$self->{preference}   = unpack( "\@$offset n", $$data );
	$self->{intermediate} = Net::DNS::DomainName2535->decode( $data, $offset + 2, @opaque );
	return;
}


sub _encode_rdata {			## encode rdata as wire-format octet string
	my ( $self, $offset, @opaque ) = @_;

	return pack 'n a*', $self->preference, $self->{intermediate}->encode( $offset + 2, @opaque );
}


sub _format_rdata {			## format rdata portion of RR string.
	my $self = shift;

	return join ' ', $self->preference, $self->{intermediate}->string;
}


sub _parse_rdata {			## populate RR from rdata in argument list
	my ( $self, @argument ) = @_;

	for (qw(preference intermediate)) { $self->$_( shift @argument ) }
	return;
}


sub preference {
	my ( $self, @value ) = @_;
	for (@value) { $self->{preference} = 0 + $_ }
	return $self->{preference} || 0;
}


sub intermediate {
	my ( $self, @value ) = @_;
	for (@value) { $self->{intermediate} = Net::DNS::DomainName2535->new($_) }
	return $self->{intermediate} ? $self->{intermediate}->name : undef;
}


my $function = sub {			## sort RRs in numerically ascending order.
	return $Net::DNS::a->{'preference'} <=> $Net::DNS::b->{'preference'};
};

__PACKAGE__->set_rrsort_func( 'preference', $function );

__PACKAGE__->set_rrsort_func( 'default_sort', $function );


1;
__END__