File Coverage

blib/lib/Net/DNS/RR/RP.pm

Criterion	Covered	Total	%
statement	42	42	100.0
branch	4	4	100.0
path			n/a
condition			n/a
subroutine	12	12	100.0
pod	2	2	100.0
total	60	60	100.0

package Net::DNS::RR::RP;

use strict;
use warnings;
our $VERSION = (qw$Id: RP.pm 2002 2025-01-07 09:57:46Z willem $)[2];

use base qw(Net::DNS::RR);


=head1 NAME

Net::DNS::RR::RP - DNS RP resource record

=cut

use integer;

use Net::DNS::DomainName;
use Net::DNS::Mailbox;


sub _decode_rdata {			## decode rdata from wire-format octet string
	my ( $self, $data, $offset, @opaque ) = @_;

	( $self->{mbox}, $offset ) = Net::DNS::Mailbox2535->decode( $data, $offset, @opaque );
	$self->{txtdname} = Net::DNS::DomainName2535->decode( $data, $offset, @opaque );
	return;
}


sub _encode_rdata {			## encode rdata as wire-format octet string
	my ( $self, $offset, @opaque ) = @_;

	my $txtdname = $self->{txtdname};
	my $rdata    = $self->{mbox}->encode( $offset, @opaque );
	$rdata .= $txtdname->encode( $offset + length($rdata), @opaque );
	return $rdata;
}


sub _format_rdata {			## format rdata portion of RR string.
	my $self = shift;

	my @rdata = ( $self->{mbox}->string, $self->{txtdname}->string );
	return @rdata;
}


sub _parse_rdata {			## populate RR from rdata in argument list
	my ( $self, @argument ) = @_;

	for (qw(mbox txtdname)) { $self->$_( shift @argument ) }
	return;
}


sub mbox {
	my ( $self, @value ) = @_;
	for (@value) { $self->{mbox} = Net::DNS::Mailbox2535->new($_) }
	return $self->{mbox} ? $self->{mbox}->address : undef;
}


sub txtdname {
	my ( $self, @value ) = @_;
	for (@value) { $self->{txtdname} = Net::DNS::DomainName2535->new($_) }
	return $self->{txtdname} ? $self->{txtdname}->name : undef;
}


1;
__END__