File Coverage

blib/lib/Net/DNS/RR/ISDN.pm

Criterion	Covered	Total	%
statement	41	41	100.0
branch	4	4	100.0
path			n/a
condition			n/a
subroutine	13	13	100.0
pod	3	3	100.0
total	61	61	100.0

package Net::DNS::RR::ISDN;

use strict;
use warnings;
our $VERSION = (qw$Id: ISDN.pm 2002 2025-01-07 09:57:46Z willem $)[2];

use base qw(Net::DNS::RR);


=head1 NAME

Net::DNS::RR::ISDN - DNS ISDN resource record

=cut

use integer;

use Net::DNS::Text;


sub _decode_rdata {			## decode rdata from wire-format octet string
	my ( $self, $data, $offset ) = @_;

	( $self->{address}, $offset ) = Net::DNS::Text->decode( $data, $offset );
	( $self->{sa},	    $offset ) = Net::DNS::Text->decode( $data, $offset );
	return;
}


sub _encode_rdata {			## encode rdata as wire-format octet string
	my $self = shift;

	my $address = $self->{address};
	return join '', $address->encode, $self->{sa}->encode;
}


sub _format_rdata {			## format rdata portion of RR string.
	my $self = shift;

	my $address = $self->{address};
	return join ' ', $address->string, $self->{sa}->string;
}


sub _parse_rdata {			## populate RR from rdata in argument list
	my ( $self, @argument ) = @_;

	$self->address( shift @argument );
	$self->sa(@argument);
	return;
}


sub _defaults {				## specify RR attribute default values
	my $self = shift;

	$self->sa('');
	return;
}


sub address {
	my ( $self, @value ) = @_;
	for (@value) { $self->{address} = Net::DNS::Text->new($_) }
	return $self->{address} ? $self->{address}->value : undef;
}


sub sa {
	my ( $self, @value ) = @_;
	for (@value) { $self->{sa} = Net::DNS::Text->new($_) }
	return $self->{sa} ? $self->{sa}->value : undef;
}


sub ISDNaddress { return &address; }


1;
__END__