File Coverage

blib/lib/Net/DNS/RR/HINFO.pm

Criterion	Covered	Total	%
statement	35	35	100.0
branch	4	4	100.0
path			n/a
condition			n/a
subroutine	11	11	100.0
pod	2	2	100.0
total	52	52	100.0

package Net::DNS::RR::HINFO;

use strict;
use warnings;
our $VERSION = (qw$Id: HINFO.pm 2003 2025-01-21 12:06:06Z willem $)[2];

use base qw(Net::DNS::RR);


=head1 NAME

Net::DNS::RR::HINFO - DNS HINFO resource record

=cut

use integer;

use Net::DNS::Text;


sub _decode_rdata {			## decode rdata from wire-format octet string
	my ( $self, $data, $offset ) = @_;

	( $self->{cpu}, $offset ) = Net::DNS::Text->decode( $data, $offset );
	( $self->{os},	$offset ) = Net::DNS::Text->decode( $data, $offset );
	return;
}


sub _encode_rdata {			## encode rdata as wire-format octet string
	my $self = shift;

	return join '', $self->{cpu}->encode, $self->{os}->encode;
}


sub _format_rdata {			## format rdata portion of RR string.
	my $self = shift;

	return join ' ', $self->{cpu}->string, $self->{os}->string;
}


sub _parse_rdata {			## populate RR from rdata in argument list
	my ( $self, @argument ) = @_;

	$self->cpu( shift @argument );
	$self->os(@argument);
	return;
}


sub cpu {
	my ( $self, @value ) = @_;
	for (@value) { $self->{cpu} = Net::DNS::Text->new($_) }
	return $self->{cpu} ? $self->{cpu}->value : undef;
}


sub os {
	my ( $self, @value ) = @_;
	for (@value) { $self->{os} = Net::DNS::Text->new($_) }
	return $self->{os} ? $self->{os}->value : undef;
}


1;
__END__