File Coverage

blib/lib/Net/DNS/RR/AFSDB.pm

Criterion	Covered	Total	%
statement	37	37	100.0
branch	2	2	100.0
path			n/a
condition	2	2	100.0
subroutine	11	11	100.0
pod	2	2	100.0
total	54	54	100.0

package Net::DNS::RR::AFSDB;

use strict;
use warnings;
our $VERSION = (qw$Id: AFSDB.pm 2002 2025-01-07 09:57:46Z willem $)[2];

use base qw(Net::DNS::RR);


=head1 NAME

Net::DNS::RR::AFSDB - DNS AFSDB resource record

=cut

use integer;

use Net::DNS::DomainName;


sub _decode_rdata {			## decode rdata from wire-format octet string
	my ( $self, $data, $offset, @opaque ) = @_;

	$self->{subtype}  = unpack "\@$offset n", $$data;
	$self->{hostname} = Net::DNS::DomainName2535->decode( $data, $offset + 2, @opaque );
	return;
}


sub _encode_rdata {			## encode rdata as wire-format octet string
	my ( $self, $offset, @opaque ) = @_;

	my $hostname = $self->{hostname};
	return pack 'n a*', $self->subtype, $hostname->encode( $offset + 2, @opaque );
}


sub _format_rdata {			## format rdata portion of RR string.
	my $self = shift;

	my $hostname = $self->{hostname};
	return join ' ', $self->subtype, $hostname->string;
}


sub _parse_rdata {			## populate RR from rdata in argument list
	my ( $self, @argument ) = @_;

	for (qw(subtype hostname)) { $self->$_( shift @argument ) }
	return;
}


sub subtype {
	my ( $self, @value ) = @_;
	for (@value) { $self->{subtype} = 0 + $_ }
	return $self->{subtype} || 0;
}


sub hostname {
	my ( $self, @value ) = @_;
	for (@value) { $self->{hostname} = Net::DNS::DomainName2535->new($_) }
	return $self->{hostname} ? $self->{hostname}->name : undef;
}


1;
__END__