File Coverage

blib/lib/Net/DNS/RR/MINFO.pm

Criterion	Covered	Total	%
statement	39	39	100.0
branch	4	4	100.0
condition			n/a
subroutine	11	11	100.0
pod	2	2	100.0
total	56	56	100.0

package Net::DNS::RR::MINFO;

use strict;
use warnings;
our $VERSION = (qw$Id: MINFO.pm 2002 2025-01-07 09:57:46Z willem $)[2];

use base qw(Net::DNS::RR);


=head1 NAME

Net::DNS::RR::MINFO - DNS MINFO resource record

=cut

use integer;

use Net::DNS::Mailbox;


sub _decode_rdata {			## decode rdata from wire-format octet string
	my ( $self, $data, $offset, @opaque ) = @_;

	( $self->{rmailbx}, $offset ) = Net::DNS::Mailbox1035->decode( $data, $offset, @opaque );
	( $self->{emailbx}, $offset ) = Net::DNS::Mailbox1035->decode( $data, $offset, @opaque );
	return;
}


sub _encode_rdata {			## encode rdata as wire-format octet string
	my ( $self,   @argument ) = @_;
	my ( $offset, @opaque )	  = @argument;

	my $rdata = $self->{rmailbx}->encode(@argument);
	$rdata .= $self->{emailbx}->encode( $offset + length $rdata, @opaque );
	return $rdata;
}


sub _format_rdata {			## format rdata portion of RR string.
	my $self = shift;

	my @rdata = ( $self->{rmailbx}->string, $self->{emailbx}->string );
	return @rdata;
}


sub _parse_rdata {			## populate RR from rdata in argument list
	my ( $self, @argument ) = @_;

	for (qw(rmailbx emailbx)) { $self->$_( shift @argument ) }
	return;
}


sub rmailbx {
	my ( $self, @value ) = @_;
	for (@value) { $self->{rmailbx} = Net::DNS::Mailbox1035->new($_) }
	return $self->{rmailbx} ? $self->{rmailbx}->address : undef;
}


sub emailbx {
	my ( $self, @value ) = @_;
	for (@value) { $self->{emailbx} = Net::DNS::Mailbox1035->new($_) }
	return $self->{emailbx} ? $self->{emailbx}->address : undef;
}


1;
__END__