File Coverage

blib/lib/Net/Async/MCP/Transport/InProcess.pm

Criterion	Covered	Total	%
statement	34	41	82.9
branch	9	16	56.2
condition	1	3	33.3
subroutine	9	12	75.0
pod	4	4	100.0
total	57	76	75.0

package Net::Async::MCP::Transport::InProcess;
# ABSTRACT: In-process MCP transport via direct MCP::Server calls
our $VERSION = '0.002';
use strict;
use warnings;

use Future;
use Scalar::Util qw( blessed );
use Carp qw( croak );


sub new {
  my ( $class, %args ) = @_;
  croak "server is required" unless $args{server};
  return bless {
    server  => $args{server},
    next_id => 0,
  }, $class;
}


sub send_request {
  my ( $self, $method, $params ) = @_;

  my $id = ++$self->{next_id};
  my $request = {
    jsonrpc => '2.0',
    id      => $id,
    method  => $method,
    defined $params ? ( params => $params ) : (),
  };

  my $response = $self->{server}->handle($request, {});

  # Handle Mojo::Promise from async MCP tools
  if (blessed($response) && $response->isa('Mojo::Promise')) {
    my ( $resolved, $error );
    $response->then(
      sub { $resolved = $_[0] },
      sub { $error = $_[0] },
    )->wait;
    return Future->fail("MCP async tool error: $error") if $error;
    $response = $resolved;
  }

  return $self->_process_response($response);
}


sub send_notification {
  my ( $self, $method, $params ) = @_;

  my $request = {
    jsonrpc => '2.0',
    method  => $method,
    defined $params ? ( params => $params ) : (),
  };

  $self->{server}->handle($request, {});
  return Future->done;
}


sub close { Future->done }


sub _process_response {
  my ( $self, $response ) = @_;

  return Future->fail("No response from MCP server") unless $response;
  return Future->fail("Invalid response from MCP server")
    unless ref $response eq 'HASH';

  if (my $err = $response->{error}) {
    return Future->fail("MCP error $err->{code}: $err->{message}");
  }

  return Future->done($response->{result});
}


1;

__END__